File Coverage

blib/lib/HTTP/ProxySelector.pm

Criterion	Covered	Total	%
statement	15	59	25.4
branch	0	14	0.0
condition	0	15	0.0
subroutine	5	10	50.0
pod	3	4	75.0
total	23	102	22.5

package HTTP::ProxySelector;

use 5.006;
use strict;
use warnings;
use integer;
use LWP::UserAgent;
our $VERSION = '0.02';

# rand() is used, let's try to make the most of it...
srand;

# Constructor. Enables Inheritance
sub new {
	my $this = shift;
	my $class = ref($this) || $this;
	my $self = {};
	bless $self, $class;

	if (@_) {
		my %options = @_;
		$self->{options} = \%options;
	}

	# Defaults
	unless ($self->{options}{sites}) {
		@{$self->{options}{sites}} = ('http://www.multiproxy.org/txt_anon/proxy.txt','http://www.samair.ru/proxy/fresh-proxy-list.htm');
	}
	$self->{options}{num_tries} ||= 5;
	$self->{options}{testsite} ||= 'http://www.google.com';
	$self->{options}{testflag} ||= 1;

	# Return initialized object
	return $self;
}

# Accept an anonymous proxy
sub set_proxy {
	my ($self) = @_;
	my ($counter, $rc) = (0,0);
	do {
		$rc = _set_proxy(@_);
		++$counter;
	}
	until (($rc ne 'retest') || ($counter > $self->{options}{num_tries}));
	$rc = 'All proxies checked failed to perform as expected' if ($rc eq 'retest');
	return $rc;
}

sub _set_proxy {
	my ($self, $ua) = @_;
	my $rc;
	eval {
		# From now, things can only go wrong :-)
		$rc = 0;

		my $list_page = $self->{options}{sites}[int(rand(scalar(@{$self->{options}{sites}})))];
		my $response = $ua->get($list_page);
		my @proxy_list = $response->content() =~ /([\w\.\-]{7,}:\d{1,5})/g;
		unless (@proxy_list) {
			warn "Couldn't find any proxies in $list_page\n";
			$rc = 1;
		}
		$self->{selected_proxy} = $proxy_list[int(rand(@proxy_list))];
		$ua->proxy(['http', 'ftp'], 'http://' . $self->{selected_proxy});

		# Proxy test, if required
		$rc = $self->test_proxy($ua) if (($self->{options}{testflag}) && ($rc == 0));
	};
	if ($@) {
		warn("Error occured in set_proxy - $@, Last system error: $!\n");
		return $@;
	}
	return $rc;

}
# Tell the caller what proxy has been selected
sub get_proxy {
	my $self = shift;
	return $self->{selected_proxy};
}

# Test the proxy by trying to access a site
# Return 0 for success, 1 for failure.
sub test_proxy {
	my ($self, $ua) = @_;
	my $response = $ua->get($self->{options}{testsite});
	$response->is_success() ? return 0 : return 1;
}

1;
__END__