File Coverage

blib/lib/HTML/Widgets/NavMenu/ToJSON.pm

Criterion	Covered	Total	%
statement	42	42	100.0
branch	6	8	75.0
condition			n/a
subroutine	10	10	100.0
pod	1	1	100.0
total	59	61	96.7

package HTML::Widgets::NavMenu::ToJSON;

use 5.008;

use strict;
use warnings FATAL => 'all';

use Carp;

use parent 'HTML::Widgets::NavMenu::Object';

use JSON::MaybeXS 1.002002 ();


our $VERSION = '0.0.7';


__PACKAGE__->mk_acc_ref(
    [
        qw(
        _data_persistence_store
        _tree_contents
        ),
    ]
);

sub _init
{
    my ($self, $args) = @_;

    $self->_data_persistence_store(
        $args->{'data_persistence_store'}
    ) or Carp::confess("No data_persistence_store specified.");

    $self->_tree_contents(
        $args->{'tree_contents'}
    ) or Carp::confess("No tree_contents specified.");

    return;
}

sub _get_id_for_url
{
    my ($self, $url) = @_;
    return $self->_data_persistence_store->get_id_for_url($url);
}


sub output_as_json
{
    my $self = shift;

    my $persistence = $self->_data_persistence_store();

    $persistence->load;

    my $process_sub_tree;

    $process_sub_tree = sub
    {
        my ($sub_tree) = @_;

        my @keys = (grep { $_ ne 'subs' } keys %{$sub_tree});

        my $has_subs = exists($sub_tree->{subs});

        return
        {
            (exists($sub_tree->{url})
                ? (id => $self->_get_id_for_url($sub_tree->{url}), )
                : ()
            ),
            (map { $_ => $sub_tree->{$_} } @keys),
            $has_subs
            ?  (subs => [ map { $process_sub_tree->($_) }
                    grep { ! exists($_->{separator}) }
                    @{$sub_tree->{subs}}
                ])
            : (),
        };
    };

    my $ret = JSON::MaybeXS->new(utf8 => 1, canonical => 1)->encode(
        $process_sub_tree->($self->_tree_contents)->{'subs'}
    );

    $persistence->save;

    return $ret;
}


1; # End of HTML::Widgets::NavMenu::ToJSON

__END__