File Coverage

blib/lib/HTML/Highlighter.pm

Criterion	Covered	Total	%
statement	60	60	100.0
branch	13	16	81.2
condition	1	3	33.3
subroutine	10	10	100.0
pod	1	1	100.0
total	85	90	94.4

package HTML::Highlighter;

use strict;
use warnings;

use HTML::Parser;
use Plack::Request;
use Plack::Util::Accessor qw/param callback/;
use List::Util qw/first/;

use parent 'Plack::Middleware';

use 5.008_001;
our $VERSION = "0.05";
$VERSION = eval $VERSION;

sub call {
  my ($self, $env) = @_;

  my $res = $self->app->($env);

  $self->response_cb( $res, sub {
    my $res = shift;
    my $h = Plack::Util::headers($res->[1]);

    my $type = $h->get("Content-Type");
    return $res unless $type and $type =~ /html/i;

    $self->callback->($env) if $self->callback;

    my $req = Plack::Request->new($env);
    $self->param("") unless defined $self->param;

    my $highlights = do {
      if ($env->{'psgix.highlight'}) {
        $env->{'psgix.highlight'};
      } else {
        my $param = first {$req->parameters->{$_}} ($self->param, qw/q query search highlight/);
        $param ? $req->parameters->{$param} : undef;
      }
    };

    return $res unless $highlights;
    my @highlights = split /\s+/, $highlights;

    my $html;
    my $p = HTML::Parser->new(
      api_version => 3,
      handlers => {
        default => [
          sub {
            $html .= $_[0]
          }, "text"
        ],
        text => [
          sub {
            for my $highlight (@highlights) {
              $_[0] =~ s/(\Q$highlight\E)/$1<\/span>/gi;
            }
            $html .= $_[0]
          }, "text"
        ],
        end_document => [
          sub {
            $res->[2] = [$html];
            $h->set('Content-Length' => length $html)
          }
        ],
      }
    );

    my $done;

    return sub {
      my $chunk = shift;
      return if $done;

      if (defined $chunk) {
        $p->parse($chunk);
        return '';
      } else {
        $p->eof;
        $done = 1;
        return $html;
      }
    };
  });
}

1;

__END__