File Coverage

blib/lib/Guacamole/Dumper.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	10	12	83.3
condition	3	4	75.0
subroutine	7	7	100.0
pod	0	1	0.0
total	55	59	93.2

package Guacamole::Dumper;
our $AUTHORITY = 'cpan:XSAWYERX';
# ABSTRACT: Dump Guacamole ASTs
$Guacamole::Dumper::VERSION = '0.008';
use strict;
use warnings;

use List::Util qw/any sum/;
use Exporter "import";

our @EXPORT_OK = qw/dump_tree/;

sub dump_tree {
    my ($tree, $offset) = @_;
    return join "", map "$_\n", _dump_tree_inner($tree, "", $offset);
}

sub _dump_tree_inner {
    my ($tree, $indent, $offset) = @_;
    $indent //= "";
    $offset //= "  ";

    ref $tree eq 'HASH'
        or die "Bad token object: $tree";

    my $head = $tree->{
        $tree->{'type'} eq 'lexeme'
        ? 'value'
        : 'name'
    };

    my @tail = $tree->{'type'} eq 'lexeme'
             ? ()
             : @{ $tree->{'children'} };

    if ( any { ref $_ } @tail ) {
        my @rest = map { ref $_ ? _dump_tree_inner($_, "$indent$offset", $offset) : "$indent$offset'$_'" } @tail;

        my @clean = map { s/^\s+//r } @rest;
        if (sum(map length, @clean) < 40) {
            my @items = ($head, @clean);
            return ("$indent(@items)");
        }

        $rest[-1] .= ")";
        return ("$indent($head", @rest);
    } else {
        my @tailq = map "'$_'", @tail;
        my @items = ($head, @tailq);
        return ("$indent(@items)");
    }
}

1;

__END__