File Coverage

blib/lib/Graph/Writer/Graph6.pm

Criterion	Covered	Total	%
statement	38	38	100.0
branch	4	4	100.0
condition	6	6	100.0
subroutine	9	9	100.0
pod			n/a
total	57	57	100.0

# Copyright 2015, 2016, 2017 Kevin Ryde
#
# This file is part of Graph-Graph6.
#
# Graph-Graph6 is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 3, or (at your option) any later
# version.
#
# Graph-Graph6 is distributed in the hope that it will be useful, but WITHOUT
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
# more details.
#
# You should have received a copy of the GNU General Public License along
# with Graph-Graph6.  If not, see .

package Graph::Writer::Graph6;
use 5.004;
use strict;
use Graph::Graph6;
use Graph::Writer;

use vars '@ISA','$VERSION';
@ISA = ('Graph::Writer');
$VERSION = 7;


sub _init  {
  my ($self,%param) = @_;
  $self->SUPER::_init();
  %$self = (format => 'graph6',
            %$self,
            %param);
}

# $graph is a Graph.pm object
# return true if there is an edge either direction between $v1 and $v2
sub _has_edge_either_directed {
  my ($graph, $v1, $v2) = @_;
  return ($graph->has_edge($v1,$v2) || $graph->has_edge($v2,$v1));
}

sub _write_graph {
  my ($self, $graph, $fh) = @_;

  my @vertices = sort $graph->vertices;
  my @edge_options;
  my $format = $self->{'format'};
  if ($format eq 'sparse6') {
    my @edges = $graph->edges;  # [ $from_name, $to_name ]
    ### @edges

    # as [$from,$to] numbers
    my %vertex_to_num = map { $vertices[$_] => $_ } 0 .. $#vertices;
    @edges = map { my $from = $vertex_to_num{$_->[0]};
                   my $to   = $vertex_to_num{$_->[1]};
                   [$from, $to]
                 } @edges;
    @edge_options = (edge_aref => \@edges);
  } else {
    my $has_edge_either = ($graph->is_directed && $format ne 'digraph6'
                           ? \&_has_edge_either_directed

                           # graph undirected, or directed and format digraph
                           : 'has_edge');
    @edge_options
      = (edge_predicate => sub {
           my ($from, $to) = @_;
           return $graph->$has_edge_either($vertices[$from], $vertices[$to]);
         });
  }

  Graph::Graph6::write_graph
      (format => $format,
       header => $self->{'header'},
       fh     => $fh,
       num_vertices => scalar(@vertices),
       @edge_options);
  return 1;
}

1;
__END__