File Coverage

blib/lib/Github/Hooks/Receiver.pm

Criterion	Covered	Total	%
statement	57	68	83.8
branch	16	22	72.7
condition	4	4	100.0
subroutine	13	14	92.8
pod	0	4	0.0
total	90	112	80.3

package Github::Hooks::Receiver;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.02";

use Github::Hooks::Receiver::Event;

use JSON;
use Plack::Request;
use Class::Accessor::Lite (
    new => 1,
    ro => [qw/secret/],
);
use Digest::SHA;
use String::Compare::ConstantTime;

sub events { shift->{events} ||= {} }

sub to_app {
    my $self = shift;
    sub {
        my $env = shift;
        my $req = Plack::Request->new($env);
        if ($req->method ne 'POST') {
            return [400, [], ['BAD REQUEST']];
        }

        # verify signature
        if ($self->secret) {
            my $expected = 'sha1=' . Digest::SHA::hmac_sha1_hex($req->content, $self->secret);
            my $actual = $req->header('X-Hub-Signature') || '';
            if (!String::Compare::ConstantTime::equals($expected, $actual)) {
                return [400, [], ['BAD REQUEST']];
            }
        }

        # Parse JSON payload
        my $payload_json;
        if (lc $req->header('content-type') eq 'application/json') {
            $payload_json = $req->content;
        } elsif (lc $req->header('content-type') eq 'application/x-www-form-urlencoded') {
            $payload_json = $req->param('payload');
        }
        my $payload = eval { decode_json $payload_json }
            or return [400, [], ['BAD REQUEST']];

        my $event_name = $req->header('X-GitHub-Event');
        my $event = Github::Hooks::Receiver::Event->new(
            payload => $payload,
            event   => $event_name,
        );

        if (my $code = $self->events->{''}) {
            $code->($event, $req);
        }
        if (my $code = $self->events->{$event_name}) {
            $code->($event, $req);
        }

        [200, [], ['OK']];
    };
}

sub on {
    my $self = shift;
    my ($event, $code) = @_;
    if (ref $event eq 'CODE') {
        $code  = $event;
        $event = '';
    }
    $self->events->{$event} = $code;
}

sub run {
    my $self = shift;
    my %opts = @_ == 1 ? %{$_[0]} : @_;

    my %server;
    my $server = delete $opts{server};
    $server{server} = $server if $server;

    my @options = %opts;
    require Plack::Runner;

    my $runner = Plack::Runner->new(
        %server,
        options => \@options,
    );
    $runner->run($self->to_app);
}

1;
__END__