File Coverage

blib/lib/Games/Sudoku/Component/Base.pm

Criterion	Covered	Total	%
statement	42	46	91.3
branch	12	24	50.0
condition	18	36	50.0
subroutine	10	11	90.9
pod	4	4	100.0
total	86	121	71.0

package Games::Sudoku::Component::Base;
{
  use strict;
  use warnings;
  use Carp;

  our $VERSION = '0.01';

  sub new {
    my $class = shift;
    my $this  = bless {}, (ref $class || $class);

    my %options = ref $_[0] ? %{ $_[0] } : @_;

    my $size      = $options{size}         || 0;
    my $bl_width  = $options{block_width}  || 0;
    my $bl_height = $options{block_height} || 0;

    if ($bl_width and $bl_height and $bl_width && $bl_height) {
      $size = $bl_width * $bl_height;
    }
    elsif ($size and $size == int(sqrt($size)) ** 2) {
      $bl_width = $bl_height = int(sqrt($size));
    }
    elsif ($size or $bl_width or $bl_height) {
      croak "Invalid size: $size" if $size;
      croak "Invalid block: width $bl_width, height $bl_height"
        if $bl_width || $bl_height;
    }
    else {
      $size = 9;
      $bl_width = $bl_height = 3;
    }

    $this->{size}         = $size;
    $this->{block_width}  = $bl_width;
    $this->{block_height} = $bl_height;

    $this->_initialize(%options);

    $this;
  }

  sub _initialize {
    my ($this, %options) = @_;
  }

  sub _check {
    my ($this, $value) = @_;

    croak "Invalid value: undef"  unless defined $value;
    croak "Invalid value: $value" if $value > $this->{size} || $value < 1;

    $value;
  }

  sub _check0 {
    my ($this, $value) = @_;

    croak "Invalid value: undef"  unless defined $value;
    croak "Invalid value: $value" if $value > $this->{size} || $value < 0;

    $value;
  }

  sub _block_id {
    my ($this, $row, $col) = @_;

    croak "Invalid row: $row" unless $this->_check($row);
    croak "Invalid col: $col" unless $this->_check($col);

    my $blockrow  = int(($row - 1) / $this->{block_height});
    my $blockcol  = int(($col - 1) / $this->{block_width});

    $blockrow * $this->{block_height} + $blockcol + 1;
  }

  sub size         { $_[0]->{size} }
  sub block_width  { $_[0]->{block_width} }
  sub block_height { $_[0]->{block_height} }
}

1;
__END__