File Coverage

blib/lib/Games/Solitaire/Verify/Move.pm

Criterion	Covered	Total	%
statement	47	48	97.9
branch	13	14	92.8
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	66	68	97.0

package Games::Solitaire::Verify::Move;
$Games::Solitaire::Verify::Move::VERSION = '0.2403';
use warnings;
use strict;


use parent 'Games::Solitaire::Verify::Base';

use Games::Solitaire::Verify::Exception ();

__PACKAGE__->mk_acc_ref(
    [
        qw(
            source_type
            dest_type
            source
            dest
            num_cards
            _game
            )
    ]
);


sub _from_fcs_string
{
    my ( $self, $str ) = @_;

    if ( $str =~ m{\AMove a card from stack (\d+) to the foundations\z} )
    {
        my $source = $1;

        $self->source_type("stack");
        $self->dest_type("foundation");

        $self->source($source);
    }
    elsif ( $str =~ m{\AMove a card from freecell (\d+) to the foundations\z} )
    {
        my $source = $1;

        $self->source_type("freecell");
        $self->dest_type("foundation");

        $self->source($source);
    }
    elsif ( $str =~ m{\AMove a card from freecell (\d+) to stack (\d+)\z} )
    {
        my ( $source, $dest ) = ( $1, $2 );

        $self->source_type("freecell");
        $self->dest_type("stack");

        $self->source($source);
        $self->dest($dest);
    }
    elsif ( $str =~ m{\AMove a card from stack (\d+) to freecell (\d+)\z} )
    {
        my ( $source, $dest ) = ( $1, $2 );

        $self->source_type("stack");
        $self->dest_type("freecell");

        $self->source($source);
        $self->dest($dest);
    }
    elsif ( $str =~ m{\AMove (\d+) cards from stack (\d+) to stack (\d+)\z} )
    {
        my ( $num_cards, $source, $dest ) = ( $1, $2, $3 );

        $self->source_type("stack");
        $self->dest_type("stack");

        $self->source($source);
        $self->dest($dest);
        $self->num_cards($num_cards);
    }
    elsif ( $str =~
        m{\AMove the sequence on top of Stack (\d+) to the foundations\z} )
    {
        my $source = $1;

        $self->source_type("stack_seq");
        $self->dest_type("foundation");

        $self->source($source);
    }
    else
    {
        Games::Solitaire::Verify::Exception::Parse::FCS->throw(
            error => "Cannot parse 'FCS' String", );
    }
}

sub _init
{
    my ( $self, $args ) = @_;

    $self->_game( $args->{game} );

    if ( exists( $args->{fcs_string} ) )
    {
        return $self->_from_fcs_string( $args->{fcs_string} );
    }
    return ();
}


1;    # End of Games::Solitaire::Verify::Move

__END__