File Coverage

blib/lib/FusionInventory/Agent/Tools/AIX.pm

Criterion	Covered	Total	%
statement	18	18	100.0
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	24	24	100.0

package FusionInventory::Agent::Tools::AIX;

use strict;
use warnings;
use base 'Exporter';

use English qw(-no_match_vars);

use FusionInventory::Agent::Tools;
use Memoize;

our @EXPORT = qw(
    getLsvpdInfos
    getAdaptersFromLsdev
);

memoize('getLsvpdInfos');
memoize('getAdaptersFromLsdev');

sub getLsvpdInfos {
    my (%params) = (
        command => 'lsvpd',
        @_
    );

    my $handle = getFileHandle(%params);
    return unless $handle;

    my @devices;
    my $device;

    # skip first lines
    while (my $line = <$handle>) {
        last if $line =~ /^\*FC \?+/;
    }

    while (my $line = <$handle>) {
        if ($line =~ /^\*FC \?+/) {
            # block delimiter
            push @devices, $device;
            undef $device;
            next;
        }

        chomp $line;
        next unless $line =~ /^\* ([A-Z]{2}) \s+ (.*\S)/x;
        $device->{$1} = $2;
    }
    close $handle;

    # last device
    push @devices, $device;

    return @devices;
}

sub getAdaptersFromLsdev {
    my (%params) = (
        command => 'lsdev -Cc adapter -F "name:type:description"',
        @_
    );

    my $handle = getFileHandle(%params);
    return unless $handle;

    my @adapters;

    while (my $line = <$handle>) {
        chomp $line;
        my @info = split(/:/, $line);
        push @adapters, {
            NAME        => $info[0],
            TYPE        => $info[1],
            DESCRIPTION => $info[2]
        };
    }
    close $handle;

    return @adapters;
}

1;
__END__