File Coverage

blib/lib/Form/Tiny/Plugin/Diva.pm

Criterion	Covered	Total	%
statement	42	42	100.0
branch	4	4	100.0
condition	9	11	81.8
subroutine	11	11	100.0
pod	1	1	100.0
total	67	69	97.1

package Form::Tiny::Plugin::Diva;

use v5.10;
use strict;
use warnings;

our $VERSION = '1.01';

use Form::Tiny::Plugin::Diva::Adapter;
use Form::Tiny::Plugin::Diva::MetaRole;

use parent 'Form::Tiny::Plugin';

sub plugin
{
	my ($self, $caller, $context) = @_;

	return {
		subs => {
			diva_config => sub {
				$$context = undef;
				$caller->form_meta->add_diva_config(@_);
			},
		},

		roles => [__PACKAGE__],
		meta_roles => ['Form::Tiny::Plugin::Diva::MetaRole'],
	};
}

use Scalar::Util qw(weaken);
use Moo::Role;

has 'diva' => (
	is => 'ro',
	builder => '_build_diva',
	lazy => 1,
	init_arg => undef,
);

sub _build_diva
{
	my ($self) = @_;
	my %config = %{$self->form_meta->diva_config};

	my @fields;
	my @hidden;

	for my $field (@{$self->field_defs}) {
		my %field_data = (
			%{$field->data // {type => 'hidden'}},
			name => $field->name,
		);

		if ($field->has_default && !exists $field_data{d} && !exists $field_data{default}) {
			$field_data{default} = $field->default->($self);
		}

		my $type = $field_data{type} // $field_data{t};
		my $push_to = lc $type eq 'hidden' ? \@hidden : \@fields;
		push @$push_to, {%field_data, comment => \%field_data};
	}

	weaken $self;
	return Form::Tiny::Plugin::Diva::Adapter->new(
		%config,
		form => \@fields,
		hidden => \@hidden,

		form_instance => $self,
	);
}

1;

__END__