File Coverage

blib/lib/Form/Tiny/Inline.pm

Criterion	Covered	Total	%
statement	79	82	96.3
branch	8	10	80.0
condition	5	7	71.4
subroutine	20	20	100.0
pod	2	4	50.0
total	114	123	92.6

package Form::Tiny::Inline;
$Form::Tiny::Inline::VERSION = '2.20';
use v5.10;
use strict;
use warnings;

sub is
{
	my ($class, @roles) = @_;

	return Form::Tiny::Inline::Builder->create(@roles);
}

sub new
{
	my ($class, @params) = @_;

	return Form::Tiny::Inline::Builder->create()->new(@params);
}

# actual inline form package
{

	package Form::Tiny::Inline::Form;
$Form::Tiny::Inline::Form::VERSION = '2.20';
use v5.10;
	use strict;
	use warnings;

	use Types::Standard qw(InstanceOf);
	use Moo;

	# NOTE: consume this role eagerly
	# normally, it is part of the Base plugin, but it is also needed to have proper set
	# of constructor parameters. Since inline forms will have roles merged into the
	# objects themselves, this needs to be done beforehand
	with 'Form::Tiny::Form';

	has '_meta' => (
		is => 'ro',
		isa => InstanceOf ['Form::Tiny::Meta'],
		required => 1,
	);

	sub form_meta
	{
		my ($self) = @_;
		return $self->_meta;
	}

	sub BUILD
	{
		my ($self) = @_;

		require Moo::Role;
		Moo::Role->apply_roles_to_object(
			$self, @{$self->_meta->form_roles}
		) if @{$self->_meta->form_roles};
	}

}

# builder package to allow adding meta roles with no package magic
{

	package Form::Tiny::Inline::Builder;
$Form::Tiny::Inline::Builder::VERSION = '2.20';
use v5.10;
	use strict;
	use warnings;

	use Types::Standard qw(Str);

	use Form::Tiny::Utils qw(trim create_anon_form_meta);

	sub _build
	{
		my ($self, %args) = @_;

		# NOTE: called with caller = undef, context_ref = undef
		# not all plugins will be compatible with this, but that's okay
		require Form::Tiny;
		my $wanted = Form::Tiny->ft_run_plugins(undef, undef, @{$self->{plugins}});

		my $meta = create_anon_form_meta(@{$wanted->{meta_roles}});
		$meta->set_form_roles($wanted->{roles});
		$meta->bootstrap;

		if ($args{fields}) {
			for my $field_name (keys %{$args{fields}}) {
				$meta->add_field(
					{
						name => $field_name,
						%{$args{fields}{$field_name}},
					}
				);
			}
		}

		for my $field (@{$args{field_defs} // []}) {
			$meta->add_field($field);
		}

		if ($args{cleaner}) {
			$meta->add_hook(cleanup => $args{cleaner});
		}

		if ($meta->can('add_filter')) {
			$meta->add_global_trim_filter;

			for my $filter (@{$args{filters} // []}) {
				$meta->add_filter(@$filter);
			}
		}

		return Form::Tiny::Inline::Form->new(%args, _meta => $meta);
	}

	sub create
	{
		my ($self, @plugins) = @_;

		@plugins = map { ucfirst lc $_ } @plugins;

		return bless {
			plugins => \@plugins
		}, $self;
	}

	sub new
	{
		my $self = shift;
		my %params;
		if (@_ == 1 && ref $_[0] eq 'HASH') {
			%params = %{$_[0]};
		}
		else {
			%params = @_;
		}

		return $self->_build(%params);
	}
}

1;

__END__