File Coverage

blib/lib/Finance/Card/Discover.pm

Criterion	Covered	Total	%
statement	26	52	50.0
branch	6	16	37.5
condition	4	15	26.6
subroutine	7	11	63.6
pod	4	4	100.0
total	47	98	47.9

package Finance::Card::Discover;

use strict;
use warnings;

use Carp qw(croak);
use LWP::UserAgent;
use URI;

our $VERSION = '0.05';
$VERSION = eval $VERSION;

sub new {
    my ($class, %params) = @_;

    croak q('username' and 'password' are required)
        unless $params{username} and $params{password};

    my $self = bless \%params, $class;

    $self->ua(
        $params{ua} || LWP::UserAgent->new(agent => "$class/$VERSION")
    );

    if ($self->{debug}) {
        my $dump_sub = sub { $_[0]->dump(maxlength => 0); return };
        $self->ua->set_my_handler(request_send  => $dump_sub);
        $self->ua->set_my_handler(response_done => $dump_sub);
    }
    elsif ($self->{compress}) {
        $self->ua->default_header(accept_encoding => 'gzip,deflate');
    }

    return $self;
}

sub ua {
    my ($self, $ua) = @_;
    if ($ua) {
        croak q('ua' must be (or derived from) an LWP::UserAgent')
            unless ref $ua and $ua->isa(q(LWP::UserAgent));
        $self->{ua} = $ua;
    }
    return $self->{ua};
}

sub response { $_[0]->{response} }

sub accounts {
    my ($self) = @_;

    my $data = $self->_request(
        msgnumber => -1,
        request    => 'getcards',
    );
    return unless $data and $data->{Total};

    require Finance::Card::Discover::Account;
    return map {
        Finance::Card::Discover::Account->new($data, $_, card => $self)
    } (1 .. $data->{Total});
}

sub _request {
    my ($self, @params) = @_;

    my $uri = URI->new('https://deskshop.discovercard.com/');
    $uri->path('/cardmembersvcs/orbiscom/WebServlet');

    # Non-standard url encoding- [.-] need escaping, perhaps others.
    (local $URI::uric = $URI::uric) =~ s/\\[.-]//g;
    $uri->query_form(
        version   => '1.0',
        startTime => 20 + int rand 100,
        user      => $self->{username},
        password  => $self->{password},
        @params,
    );

    my $res = $self->{response} = $self->ua->post($uri);
    return unless $res->is_success;

    # The response content is a url-encoded string.
    my %data = do {
        my $u = URI->new;
        $u->query($res->decoded_content);
        $u->query_form
    };
    return if not %data or 'error' eq $data{action};
    return \%data;
}


1;

__END__