File Coverage

blib/lib/File/VirusScan/Engine/Command/Kaspersky/AVP5.pm

Criterion	Covered	Total	%
statement	22	44	50.0
branch	0	14	0.0
condition	0	17	0.0
subroutine	8	9	88.8
pod	1	2	50.0
total	31	86	36.0

package File::VirusScan::Engine::Command::Kaspersky::AVP5;
use strict;
use warnings;
use Carp;

use File::VirusScan::Engine::Command;
use vars qw( @ISA );
@ISA = qw( File::VirusScan::Engine::Command );

use Cwd 'abs_path';

use File::VirusScan::Result;

sub default_arguments
{
	# TODO: should /var/run/aveserver be hardcoded?
	return [ qw( -s -p /var/run/aveserver ) ];
}

sub scan
{
	my ($self, $path) = @_;

        my $abs = abs_path($path);
        if ($abs && $abs ne $path) {
                $path = $abs;
        }

	my ($exitcode, $scan_response) = eval { $self->_run_commandline_scanner(join(' ', $self->{command}, @{ $self->{args} }, $path, '2>&1'), 'INFECTED',); };

	if($@) {
		return File::VirusScan::Result->error($@);
	}

	if(        0 == $exitcode
		|| 5 == $exitcode
		|| 6 == $exitcode)
	{

		# 0 == clean
		# 5 == disinfected
		# 6 == viruses deleted
		return File::VirusScan::Result->clean();
	}

	if(1 == $exitcode) {

		# 1 == scan incomplete
		return File::VirusScan::Result->error('Scanning interrupted');
	}

	if(        2 == $exitcode
		|| 4 == $exitcode)
	{

		# 2 == "modified or damaged virus"
		# 4 == virus
		my ($virus_name) = $scan_response =~ m/INFECTED (\S+)/;
		$virus_name ||= 'unknown-AVP5-virus';
		return File::VirusScan::Result->virus($virus_name);
	}

	if(        3 == $exitcode
		|| 8 == $exitcode)
	{

		# 3 == "suspicious" object found
		# 8 == corrupt objects found (treat as suspicious
		return File::VirusScan::Result->virus('AVP5-suspicious');
	}

	if(7 == $exitcode) {

		# 7 == AVPLinux corrupt or infected
		return File::VirusScan::Result->error('AVPLinux corrupt or infected');
	}

	return File::VirusScan::Result->error("Unknown return code from aveclient: $exitcode");
}

1;
__END__