File Coverage

blib/lib/File/Serialize/Serializer.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	4	4	100.0
condition			n/a
subroutine	17	17	100.0
pod	5	9	55.5
total	63	67	94.0

package File::Serialize::Serializer;
our $AUTHORITY = 'cpan:YANICK';
# ABSTRACT: Role for defining File::Serialize serializers
$File::Serialize::Serializer::VERSION = '1.4.0';

use strict;
use warnings;

use List::MoreUtils qw/ any all /;
use Module::Info;
use Module::Runtime qw/ use_module /;

use Role::Tiny;

requires 'extensions';  # first extension is the canonical one

requires 'serialize', 'deserialize';

sub precedence { 100 }

sub required_modules {
    my $package = shift;
    $package =~ s/^File::Serialize::Serializer:://r;
}

sub extension { ($_[0]->extensions)[0] }

sub does_extension {
   my( $self, $ext ) = @_;
   return unless $ext;
   return any { $_ eq $ext } $self->extensions;
}

sub is_operative {
    return 1 unless $_[0]->required_modules;
    all { Module::Info->new_from_module($_) } $_[0]->required_modules;
}

sub groom_serialize_options {
    my $self = shift;
    $self->groom_options(@_);
}

sub groom_deserialize_options {
    my $self = shift;
    $self->groom_options(@_);
}

sub groom_options {
    my $self = shift;
    @_;
}

before serialize => \&init;
before deserialize => \&init;

around serialize => sub {
    my( $orig, $self, $data, $options ) = @_;
    $orig->( $self, $data, $self->groom_serialize_options($options) );
};

around deserialize => sub {
    my( $orig, $self, $data, $options ) = @_;
    $orig->( $self, $data, $self->groom_deserialize_options($options) );
};

sub init {
    my $self = shift;
    use_module($_) for $self->required_modules;
}

1;

__END__