File Coverage

blib/lib/Exception/Tiny.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	7	8	87.5
condition	5	6	83.3
subroutine	13	13	100.0
pod	5	5	100.0
total	71	73	97.2

package Exception::Tiny;
use strict;
use warnings;
use 5.008005;
our $VERSION = '0.2.1';

use Data::Dumper ();
use Scalar::Util ();

use overload
    bool     => sub { 1 },
    q{""}    => 'as_string',
    fallback => 1;

use Class::Accessor::Lite (
    new => 1,
    ro  => [qw/ message file line package subroutine /]
);


sub throw {
    my $class = shift;

    my %args;
    if (@_ == 1) {
        $args{message} = shift;
    } else {
        %args = @_;
    }
    $args{message} = $class unless defined $args{message} && $args{message} ne '';

    ($args{package}, $args{file}, $args{line}) = caller(0);
    $args{subroutine} = (caller(1))[3];

    die $class->new(%args);
}

sub rethrow {
    my $self = shift;
    die $self;
}

sub as_string {
    my $self = shift;
    sprintf '%s at %s line %s.', $self->message, $self->file, $self->line;
}

sub dump {
    local $Data::Dumper::Terse = 1;
    Data::Dumper::Dumper(shift);
}

sub caught {
    my($class, $e) = @_;
    return if ref $class;
    return unless Scalar::Util::blessed($e) && UNIVERSAL::isa($e, $class);
    $e;
}

1;
__END__