File Coverage

blib/lib/Etcd.pm

Criterion	Covered	Total	%
statement	38	41	92.6
branch	7	12	58.3
condition	2	3	66.6
subroutine	12	12	100.0
pod	1	2	50.0
total	60	70	85.7

package Etcd;
$Etcd::VERSION = '0.002';
# ABSTRACT: Client library for etcd

use namespace::sweep;

use HTTP::Tiny;
use URI::Escape qw(uri_escape);
use Carp qw(croak);

use Moo;
use Type::Utils qw(class_type);
use Types::Standard qw(Str Int Bool HashRef);

has host => ( is => 'ro', isa => Str, default => '127.0.0.1' );
has port => ( is => 'ro', isa => Int, default => 4001 );

has ssl => ( is => 'ro', isa => Bool, default => 0 );

has http => ( is => 'lazy', isa => class_type('HTTP::Tiny') );
sub _build_http { HTTP::Tiny->new };

has version_prefix => ( is => 'ro', isa => Str, default => '/v2' );

has _url_base => ( is => 'lazy' );
sub _build__url_base {
    my ($self) = @_;
    ($self->ssl ? 'https' : 'http') .'://'.$self->host.':'.$self->port;
}

sub _prep_url {
    my ($self, $path, %args) = @_;
    my $trailing = $path =~ m{/$};
    my $url = $self->_url_base.join('/', map { uri_escape($_) } split('/', $path));
    $url .= '/' if $trailing;
    $url .= '?'.$self->http->www_form_urlencode(\%args) if %args;
    $url;
}

sub api_exec {
    my ($self, $path, $method, %args) = @_;
    my $res = $self->http->request($method, $self->_prep_url($path, %args));
    $res = $self->http->request($method, $res->{headers}->{location})
        if $res && $res->{status} eq 307;
    return $res if $res->{success};
    croak "$res->{status} $res->{reason}: $res->{content}" if $res->{status} >= 500;
    require Etcd::Error;
    die Etcd::Error->new_from_http($res);
}

sub server_version {
    my ($self) = @_;
    my $res = $self->api_exec('/version', 'GET');
    $res->{content};
}

with 'Etcd::Keys';
with 'Etcd::Stats';

1;

__END__