File Coverage

blib/lib/Email/MessageID.pm

Criterion	Covered	Total	%
statement	30	34	88.2
branch	6	8	75.0
condition	5	8	62.5
subroutine	9	11	81.8
pod	4	8	50.0
total	54	69	78.2

use strict;
use warnings;
package Email::MessageID 1.408;
# ABSTRACT: Generate world unique message-ids.

use overload '""' => 'as_string', fallback => 1;

#pod =head1 SYNOPSIS
#pod
#pod   use Email::MessageID;
#pod
#pod   my $mid = Email::MessageID->new->in_brackets;
#pod
#pod   print "Message-ID: $mid\x0D\x0A";
#pod
#pod =head1 DESCRIPTION
#pod
#pod Message-ids are optional, but highly recommended, headers that identify a
#pod message uniquely. This software generates a unique message-id.
#pod
#pod =method new
#pod
#pod   my $mid = Email::MessageID->new;
#pod
#pod   my $new_mid = Email::MessageID->new( host => $myhost );
#pod
#pod This class method constructs an Email::MessageID object
#pod containing a unique message-id. You may specify custom C and C
#pod parameters.
#pod
#pod By default, the C is generated from C.
#pod
#pod By default, the C is generated using C's C
#pod and the process ID.
#pod
#pod Using these values we have the ability to ensure world uniqueness down to
#pod a specific process running on a specific host, and the exact time down to
#pod six digits of microsecond precision.
#pod
#pod =cut

sub new {
    my ($class, %args) = @_;

    $args{user} ||= $class->create_user;
    $args{host} ||= $class->create_host;

    my $str = "$args{user}\@$args{host}";

    bless \$str => $class;
}

#pod =method create_host
#pod
#pod   my $domain_part = Email::MessageID->create_host;
#pod
#pod This method returns the domain part of the message-id.
#pod
#pod =cut

my $_SYS_HOSTNAME_LONG;
sub create_host {
    unless (defined $_SYS_HOSTNAME_LONG) {
      $_SYS_HOSTNAME_LONG = (eval { require Sys::Hostname::Long; 1 }) || 0;
      require Sys::Hostname unless $_SYS_HOSTNAME_LONG;
    }

    return $_SYS_HOSTNAME_LONG ? Sys::Hostname::Long::hostname_long()
                               : Sys::Hostname::hostname();
}

#pod =method create_user
#pod
#pod   my $local_part = Email::MessageID->create_user;
#pod
#pod This method returns a unique local part for the message-id.  It includes some
#pod random data and some predictable data.
#pod
#pod =cut

my @CHARS = ('A'..'F','a'..'f',0..9);

my %uniq;

sub create_user {
    my $noise = join '',
                map {; $CHARS[rand @CHARS] } (0 .. (3 + int rand 6));

    my $t = time;
    my $u = exists $uniq{$t} ? ++$uniq{$t} : (%uniq = ($t => 0))[1];

    my $user = join '.', $t . $u, $noise, $$;
    return $user;
}

#pod =method in_brackets
#pod
#pod When using Email::MessageID directly to populate the C field, be
#pod sure to use C to get the string inside angle brackets:
#pod
#pod   header => [
#pod     ...
#pod     'Message-Id' => Email::MessageID->new->in_brackets,
#pod   ],
#pod
#pod Don't make this common mistake:
#pod
#pod   header => [
#pod     ...
#pod     'Message-Id' => Email::MessageID->new->as_string, # WRONG!
#pod   ],
#pod
#pod =for Pod::Coverage address as_string host user
#pod
#pod =cut

sub user { (split /@/, ${ $_[0] }, 2)[0] }
sub host { (split /@/, ${ $_[0] }, 2)[1] }

sub in_brackets {
    my ($self) = @_;
    return "<$$self>";
}

sub address {
    my ($self) = @_;
    return "$$self";
}

sub as_string {
    my ($self) = @_;
    return "$$self";
}

1;

__END__