File Coverage

blib/lib/Elasticsearch/CxnPool/Sniff.pm

Criterion	Covered	Total	%
statement	36	36	100.0
branch	12	12	100.0
condition			n/a
subroutine	6	6	100.0
pod	2	3	66.6
total	56	57	98.2

package Elasticsearch::CxnPool::Sniff;
$Elasticsearch::CxnPool::Sniff::VERSION = '1.05';
use Moo;
with 'Elasticsearch::Role::CxnPool::Sniff', 'Elasticsearch::Role::Is_Sync';

use Elasticsearch::Util qw(throw);
use namespace::clean;

#===================================
sub next_cxn {
#===================================
    my ($self) = @_;

    $self->sniff if $self->next_sniff <= time();

    my $cxns  = $self->cxns;
    my $total = @$cxns;

    while ( 0 < $total-- ) {
        my $cxn = $cxns->[ $self->next_cxn_num ];
        return $cxn if $cxn->is_live;
    }

    throw( "NoNodes",
        "No nodes are available: [" . $self->cxns_seeds_str . ']' );
}

#===================================
sub sniff {
#===================================
    my $self = shift;

    my $cxns  = $self->cxns;
    my $total = @$cxns;
    my @skipped;

    while ( 0 < $total-- ) {
        my $cxn = $cxns->[ $self->next_cxn_num ];
        if ( $cxn->is_dead ) {
            push @skipped, $cxn;
        }
        else {
            $self->sniff_cxn($cxn) and return;
            $cxn->mark_dead;
        }
    }

    for my $cxn (@skipped) {
        $self->sniff_cxn($cxn) and return;
    }

    $self->logger->infof("No live nodes available. Trying seed nodes.");
    for my $seed ( @{ $self->seed_nodes } ) {
        my $cxn = $self->cxn_factory->new_cxn($seed);
        $self->sniff_cxn($cxn) and return;
    }

}

#===================================
sub sniff_cxn {
#===================================
    my ( $self, $cxn ) = @_;
    return $self->parse_sniff( $cxn->protocol, $cxn->sniff );
}

1;

# ABSTRACT: A CxnPool for connecting to a local cluster with a dynamic node list

__END__

=pod

=encoding UTF-8

=head1 NAME

Elasticsearch::CxnPool::Sniff - A CxnPool for connecting to a local cluster with a dynamic node list

=head1 VERSION

version 1.05

=head1 SYNOPSIS

    $e = Elasticsearch->new(
        cxn_pool => 'Sniff',
        nodes    => [
            'search1:9200',
            'search2:9200'
        ],
    );

=head1 DESCRIPTION

The L<Sniff|Elasticsearch::CxnPool::Sniff> connection pool should be used
when you B<do> have direct access to the Elasticsearch cluster, eg when
your web servers and Elasticsearch servers are on the same network.
The nodes that you specify are used to I<discover> the cluster, which is
then I<sniffed> to find the current list of live nodes that the cluster
knows about.

This sniff process is repeated regularly, or whenever a node fails,
to update the list of healthy nodes.  So if you add more nodes to your
cluster, they will be auto-discovered during a sniff.

If all sniffed nodes fail, then it falls back to sniffing the original
I<seed> nodes that you specified in C<new()>.

For L<HTTP Cxn classes|Elasticsearch::Role::Cxn::HTTP>, this module
will also dynamically detect the C<max_content_length> which the nodes
in the cluster will accept.

This class does L<Elasticsearch::Role::CxnPool::Sniff> and
L<Elasticsearch::Role::Is_Sync>.

=head1 CONFIGURATION

=head2 C<nodes>

The list of nodes to use to discover the cluster.  Can accept a single node,
multiple nodes, and defaults to C<localhost:9200> if no C<nodes> are
specified. See L<Elasticsearch::Role::Cxn::HTTP/node> for details of the node
specification.

=head2 See also

=over

=item *

L<Elasticsearch::Role::Cxn/request_timeout>

=item *

L<Elasticsearch::Role::Cxn/sniff_timeout>

=item *

L<Elasticsearch::Role::Cxn/sniff_request_timeout>

=back

=head2 Inherited configuration

From L<Elasticsearch::Role::CxnPool::Sniff>

=over

=item * L<sniff_interval|Elasticsearch::Role::CxnPool::Sniff/"sniff_interval">

=item * L<sniff_max_content_length|Elasticsearch::Role::CxnPool::Sniff/"sniff_max_content_length">

=back

From L<Elasticsearch::Role::CxnPool>

=over

=item * L<randomize_cxns|Elasticsearch::Role::CxnPool/"randomize_cxns">

=back

=head1 METHODS

=head2 C<next_cxn()>

    $cxn = $cxn_pool->next_cxn

Returns the next available live node (in round robin fashion), or
throws a C<NoNodes> error if no nodes can be sniffed from the cluster.

=head2 C<schedule_check()>

    $cxn_pool->schedule_check

Forces a sniff before the next Cxn is returned, to updated the list of healthy
nodes in the cluster.

=head2 C<sniff()>

    $bool = $cxn_pool->sniff

Sniffs the cluster and returns C<true> if the sniff was successful.

=head2 Inherited methods

From L<Elasticsearch::Role::CxnPool::Sniff>

=over

=item * L<schedule_check()|Elasticsearch::Role::CxnPool::Sniff/"schedule_check()">

=item * L<parse_sniff()|Elasticsearch::Role::CxnPool::Sniff/"parse_sniff()">

=item * L<should_accept_node()|Elasticsearch::Role::CxnPool::Sniff/"should_accept_node()">

=back

From L<Elasticsearch::Role::CxnPool>

=item * L<cxn_factory()|Elasticsearch::Role::CxnPool/"cxn_factory()">

=item * L<logger()|Elasticsearch::Role::CxnPool/"logger()">

=item * L<serializer()|Elasticsearch::Role::CxnPool/"serializer()">

=item * L<current_cxn_num()|Elasticsearch::Role::CxnPool/"current_cxn_num()">

=item * L<cxns()|Elasticsearch::Role::CxnPool/"cxns()">

=item * L<seed_nodes()|Elasticsearch::Role::CxnPool/"seed_nodes()">

=item * L<next_cxn_num()|Elasticsearch::Role::CxnPool/"next_cxn_num()">

=item * L<set_cxns()|Elasticsearch::Role::CxnPool/"set_cxns()">

=item * L<request_ok()|Elasticsearch::Role::CxnPool/"request_ok()">

=item * L<request_failed()|Elasticsearch::Role::CxnPool/"request_failed()">

=item * L<should_retry()|Elasticsearch::Role::CxnPool/"should_retry()">

=item * L<should_mark_dead()|Elasticsearch::Role::CxnPool/"should_mark_dead()">

=item * L<cxns_str()|Elasticsearch::Role::CxnPool/"cxns_str()">

=item * L<cxns_seeds_str()|Elasticsearch::Role::CxnPool/"cxns_seeds_str()">

=item * L<retries()|Elasticsearch::Role::CxnPool/"retries()">

=item * L<reset_retries()|Elasticsearch::Role::CxnPool/"reset_retries()">

=back

=head1 AUTHOR

Clinton Gormley <[e-mail]>

=head1 COPYRIGHT AND LICENSE

This software is Copyright (c) 2014 by Elasticsearch BV.

This is free software, licensed under:

  The Apache License, Version 2.0, January 2004

=cut