File Coverage

blib/lib/ETL/Yertl/Format/csv.pm

Criterion	Covered	Total	%
statement	61	61	100.0
branch	9	12	75.0
condition	6	9	66.6
subroutine	10	10	100.0
pod	3	4	75.0
total	89	96	92.7

package ETL::Yertl::Format::csv;
our $VERSION = '0.036';
# ABSTRACT: CSV read/write support for Yertl

use ETL::Yertl;
use base 'ETL::Yertl::Format';
use Module::Runtime qw( use_module );
use ETL::Yertl::Util qw( pairs );

sub new {
    my ( $class, %args ) = @_;
    $args{delimiter} ||= ',';
    return $class->SUPER::new( %args );
}

#pod =attr format_module
#pod
#pod The module being used for this format. Possible modules, in order of importance:
#pod
#pod =over 4
#pod
#pod =item L (any version)
#pod
#pod =item L (any version)
#pod
#pod =back
#pod
#pod =cut

# Pairs of module => supported version
our @FORMAT_MODULES = (
    'Text::CSV_XS' => 0,
    'Text::CSV' => 0,
);

sub format_module {
    my ( $self ) = @_;
    return $self->{_format_module} if $self->{_format_module};
    for my $format_module ( pairs @FORMAT_MODULES ) {
        eval {
            # Prototypes on use_module() make @$format_module not work correctly
            use_module( $format_module->[0], $format_module->[1] );
        };
        if ( !$@ ) {
            return $format_module->[0];
        }
    }
    die "Could not load a formatter for CSV. Please install one of the following modules:\n"
        . join( "",
            map { sprintf "\t%s (%s)", $_->[0], $_->[1] ? "version $_->[1]" : "Any version" }
            pairs @FORMAT_MODULES
        )
        . "\n";
}

sub _field_names {
    my ( $self, $new_names ) = @_;
    if ( $new_names ) {
        $self->{_field_names} = $new_names;
    }
    return $self->{_field_names} || [];
}

sub _csv {
    my ( $self ) = @_;
    return $self->{_csv} ||= $self->format_module->new({
        binary => 1, eol => $\,
        sep_char => $self->{delimiter},
    });
}

#pod =method write( DOCUMENTS )
#pod
#pod Convert the given C to CSV. Returns a CSV string.
#pod
#pod =cut

sub write {
    my ( $self, @docs ) = @_;
    my $csv = $self->_csv;
    my $str = '';
    my @names = @{ $self->_field_names };

    if ( !@names ) {
        @names = sort keys %{ $docs[0] };
        $csv->combine( @names );
        $str .= $csv->string . $/;
        $self->_field_names( \@names );
    }

    for my $doc ( @docs ) {
        $csv->combine( map { $doc->{ $_ } } @names );
        $str .= $csv->string . $/;
    }

    return $str;
}

#pod =method read()
#pod
#pod Read a CSV string from L and return all the documents.
#pod
#pod =cut

sub read {
    my ( $self ) = @_;
    my $fh = $self->{input} || die "No input filehandle";
    my $csv = $self->_csv;
    my @names = @{ $self->_field_names };

    if ( !@names ) {
        @names = @{ $csv->getline( $fh ) };
        $self->_field_names( \@names );
    }

    my @docs;
    while ( my $row = $csv->getline( $fh ) ) {
        push @docs, { map {; $names[ $_ ] => $row->[ $_ ] } 0..$#{ $row } };
    }

    return @docs;
}

1;

__END__