File Coverage

blib/lib/EPublisher/Target/Plugin/Mobi.pm

Criterion	Covered	Total	%
statement	15	49	30.6
branch	0	6	0.0
condition	0	19	0.0
subroutine	5	6	83.3
pod	1	1	100.0
total	21	81	25.9

package EPublisher::Target::Plugin::Mobi;

# ABSTRACT: Use Mobi format as a target for EPublisher

use strict;
use warnings;

use File::Temp;
use EBook::MOBI;
use EPublisher::Target::Base;

our @ISA = qw(EPublisher::Target::Base);

our $VERSION = 0.6;

sub deploy {
    my ($self) = @_;

    my $pods     = $self->_config->{source} || [];

    my $author         = $self->_config->{author}   || 'Perl Author';
    my $title          = $self->_config->{title}    || 'Pod Document';
    my $language       = $self->_config->{lang}     || 'en';
    my $out_filename   = $self->_config->{output}   || '';
    my $encoding       = $self->_config->{encoding} || ':encoding(UTF-8)';
    my $imgcover       = $self->_config->{cover}    || '';
    my $htmcover       = $self->_config->{htmcover} || '';

    if ( !$out_filename ) {
        my $fh = File::Temp->new;
        $out_filename = $fh->filename;
    }

    # Create an object of a book
    my $book = EBook::MOBI->new();

    # give some meta information about this book
    $book->set_filename($out_filename);
    $book->set_title   ($title);
    $book->set_author  ($author);
    $book->set_encoding($encoding);

    # create title page from an image, if set
    if ($imgcover and -e $imgcover) {
        $book->add_content( data   => "\n=image $imgcover\n\n",
                            driver => 'EBook::MOBI::Driver::POD',
                          );
        $book->add_pagebreak();
    }
    # create title page from mhtml, if set
    if ($htmcover) {
        $book->add_mhtml_content($htmcover);
        $book->add_pagebreak();
    }

    # insert a table of contents after the titlepage
    $book->add_toc_once();
    $book->add_pagebreak();

    # insert content of the book
    for my $data (@{$pods}) {

        my $chap = $data->{title};
        my $pod  = $data->{pod};

        $book->add_content( data => "\n=head1 $chap\n\n",
                            driver => 'EBook::MOBI::Driver::POD',
                          );
        # add the books text, which is e.g. in the POD format
        $book->add_content( data => $pod,
                            driver => 'EBook::MOBI::Driver::POD',
                            driver_options => {
                                pagemode => 1,
                                head0_mode => 1,
                            }
                          );
    }

    # prepare the book (e.g. calculate the references for the TOC)
    $book->make();

    # let me see how this mobi-html looks like
    #$book->print_mhtml();
    # TODO: should only print in DEBUG-MODE

    # ok, give me that mobi-book as a file!
    $book->save();


    return $out_filename;
}

1;


__END__