File Coverage

blib/lib/EAFDSS.pm

Criterion	Covered	Total	%
statement	48	55	87.2
branch	16	24	66.6
condition			n/a
subroutine	9	9	100.0
pod	2	2	100.0
total	75	90	83.3

# EAFDSS - Electronic Fiscal Signature Devices Library
#          Ειδική Ασφαλής Φορολογική Διάταξη Σήμανσης (ΕΑΦΔΣΣ)
#
# Copyright (C) 2008 Hasiotis Nikos
#
# ID: $Id: EAFDSS.pm 105 2009-05-18 10:52:03Z hasiotis $

package EAFDSS;

=head1 NAME

EAFDSS - Electronic Fiscal Signature Devices Library

=head1 SYNOPSIS

  use EAFDSS;

  my($dh) = new EAFDSS(
                  "DRIVER" => $driver . "::" . $params,
                  "SN"     => $serial,
                  "DIR"    => $sDir,
                  "DEBUG"  => $verbal
          );

  if (! $dh) {
          print("ERROR: " . EAFDSS->error() ."\n");
          exit -1;
  }

  $result = $dh->Status();
  $result = $dh->Sign($fname);
  $result = $dh->Info();
  $result = $dh->SetTime($time);
  $result = $dh->GetTime();
  $result = $dh->SetHeaders($headers);
  $result = $dh->GetHeaders();

  if ($result) {
          printf("%s\n", $result);
          exit(0);
  } else {
          my($errNo)  = $dh->error();
          my($errMsg) = $dh->errMessage($errNo);
          printf(STDERR "ERROR [0x%02X]: %s\n", $errNo, $errMsg);
          exit($errNo);
  }


=head1 DESCRIPTION

The EAFDSS module handles the communication with an Electronic Signature Device (EAFDSS).
It defines a set of methods common to all EAFDSS devices in order to communicate with the
device but also handle all necessary file housekeeping requirements by Law, like creating
A, B, C files.

=head1 ARCHITECTURE of an EAFDSS Application

This module is loosely (and shamelessly I may add) influenced by the architecture of the
DBI module. There is a layer of a basic API that is common to all EAFDSS device drivers.
Usually a developer of an EAFDSS application will only need to deal with functions only
at that level. You have to be in need of something really special to access functions
that are specific to a certain driver.


         |<-------- EAFDSS A/B type solution ------->|
         |<- Your work ->| |<--- Scope of EAFDSS --->| |<-- hardware -->|
                                .-.   .-------------.   .---------------.
         .--------------.       | |---| SDSP Driver |---| EAFDSS Device |
         |              |       |E|   `-------------'   `---------------'
         | Perl script  |  |A|  |A|   .-------------.   .---------------.
         | using EAFDSS |--|P|--|F|---| SDNP Driver |---| EAFDSS Device |
         | API methods  |  |I|  |D|   `-------------'   `---------------'
         |              |       |S|...
         `--------------'       |S|... Other drivers
                                | |...
                                `-'

=cut

use 5.006_000;
use strict;
use warnings;
use Carp;
use Class::Base;

use base qw ( Class::Base );

our($VERSION) = '0.80';

=head1 Methods

First of all you have to initialize the driver handle through the EAFDSS constructor.

=head2 init, new

Returns a newly created $dh driver handle. The DRIVER argument is a combination of a driver and
it's parameters. For instance it could be one of the following:

  EAFDSS::SDNP::127.0.0.1

or

  EAFDSS::Dummy:/tmp/dummy.eafdss

or

  Driver EAFDSS::SDSP::/dev/ttyS0

The SN argument is the Serial number of device we want to connect. Each device has it's own unique serial
number. If the device's SN does not much with the provided then you will get an error.

The DIR argument is the directory were the signature files (A, B and C) will be created. Make sure the
directory exist.

The last argument is the DEBUG. Use a true value in order to get additional information. This one is only
useful to developers of the module itself.

  my($dh) = new EAFDSS(
                  "DRIVER" => $driver . "::" . $params,
                  "SN"     => $serial,
                  "DIR"    => $sDir,
                  "DEBUG"  => $verbal
          );

  if (! $dh) {
          print("ERROR: " . EAFDSS->error() ."\n");
          exit -1;
  }

Following are the common methods to all the device drivers.

=cut

sub init {
	my($self, $config) = @_;

	if (! exists $config->{DRIVER}) {
		croak "You need to provide the Driver to use";
	} else {
		$self->{DRV}    = substr($config->{DRIVER}, 0, rindex($config->{DRIVER}, "::"));
		$self->{PARAMS} = substr($config->{DRIVER}, rindex($config->{DRIVER}, "::") + 2);
		if ($self->{PARAMS} eq '') {
			croak "You need to provide params to the driver!";
		}
	}

	if (! exists $config->{DIR}) {
		croak "You need to provide the DIR to save the singatures!";
	} else {
		$self->{DIR} = $config->{DIR};
	}

	if (! -e $self->{DIR}) {
		croak "The directory to save the singatures does not exist!";
	}

	if (! exists $config->{SN}) {
		croak "You need to provide the Serial Number of the device!";
	} else {
		$self->{SN} = $config->{SN};
	}

	$self->debug("Loading driver \"$self->{DRV}\"\n");
	eval qq { require $self->{DRV} };
	if ($@) {
		return $self->error("No such driver \"$self->{DRV}\"");
	}

	$self->debug("Initializing device with \"$self->{PARAMS}\"\n");
	my($fd) = $self->{DRV}->new(
			"PARAMS" => $self->{PARAMS},
			"SN"     => $self->{SN},
			"DIR"    => $self->{DIR},
			"DEBUG"  => $self->{_DEBUG}
		);

	if (!defined $fd) {
		return $self->error($self->{DRV}->error());
	}

	return $fd;
}

=head2 EAFDSS->available_drivers

Returns an array containing the names of drivers currently installed/supported.

  my(@drivers) = EAFDSS->available_drivers();

=cut

sub available_drivers {
	my(@drivers, $curDir, $curFile, $curDirEAFDSS);

	foreach $curDir (@INC){
		$curDirEAFDSS = $curDir . "/EAFDSS";
		next unless -d $curDirEAFDSS;

		opendir(DIR, $curDirEAFDSS) || carp "opendir $curDirEAFDSS: $!\n";
		foreach $curFile (readdir(EAFDSS::DIR)){
			next unless $curFile =~ s/\.pm$//;
			next if $curFile eq 'Base';
			next if $curFile eq 'Micrelec';
			push(@drivers, $curFile);
		}
		closedir(DIR);
	}

	return @drivers;
}


sub DESTROY {
	my($self) = shift;
}

# Preloaded methods go here.

1;
__END__