File Coverage

blib/lib/Device/RFXCOM/Decoder/OregonScale.pm

Criterion	Covered	Total	%
statement	38	38	100.0
branch	8	8	100.0
condition	6	6	100.0
subroutine	8	8	100.0
pod	2	2	100.0
total	62	62	100.0

use strict;
use warnings;
package Device::RFXCOM::Decoder::OregonScale;
$Device::RFXCOM::Decoder::OregonScale::VERSION = '1.142010';
# ABSTRACT: Device::RFXCOM::Decoder::OregonScale decode Oregon Scale RF messages


use 5.006;
use constant DEBUG => $ENV{DEVICE_RFXCOM_DECODER_OREGON_SCALE_DEBUG};
use Carp qw/croak/;
use Device::RFXCOM::Decoder qw/hi_nibble lo_nibble/;
our @ISA = qw(Device::RFXCOM::Decoder);


sub decode {
  my ($self, $parent, $message, $bytes, $bits, $result) = @_;
  if ($bits == 64 && lo_nibble($bytes->[0]) == 3) {
    return parse_gr101($self, $parent, $message, $bytes, $bits, $result);
  }
  return unless (scalar @$bytes == 7);
  return unless (($bytes->[0]&0xf0) == ($bytes->[5]&0xf0) &&
                 ($bytes->[1]&0xf) == ($bytes->[6]&0xf));
  my $weight =
    sprintf "%x%02x%x", $bytes->[5]&0x1, $bytes->[4], hi_nibble($bytes->[3]);
  return unless ($weight =~ /^\d+$/);
  $weight /= 10;
  my $dev_str = sprintf 'bwr102.%02x', hi_nibble($bytes->[1]);
  my $unknown = sprintf "%x%x", lo_nibble($bytes->[3]), hi_nibble($bytes->[2]);
  push @{$result->{messages}},
    Device::RFXCOM::Response::Sensor->new(device => $dev_str,
                                           measurement => 'weight',
                                           value => $weight,
                                           unknown => $unknown,
                                          );
  return 1;
}


sub parse_gr101 {
  my ($self, $parent, $message, $bytes, $bits, $result) = @_;

  my $weight =
    (lo_nibble($bytes->[4])<<12) + ($bytes->[3]<<4) + ($bytes->[2]>>4);
  $weight = sprintf "%.1f", $weight/400.8;
  my $dev_str = sprintf 'gr101.%02x', $bytes->[1];
  push @{$result->{messages}},
    Device::RFXCOM::Response::Sensor->new(device => $dev_str,
                                          measurement => 'weight',
                                          value => $weight);
  return 1;
}

1;

__END__