File Coverage

blib/lib/Device/Chip/SSD1306/SPI4.pm

Criterion	Covered	Total	%
statement	42	47	89.3
branch	1	2	50.0
condition			n/a
subroutine	10	11	90.9
pod	1	6	16.6
total	54	66	81.8

#  You may distribute under the terms of either the GNU General Public License
#  or the Artistic License (the same terms as Perl itself)
#
#  (C) Paul Evans, 2015-2022 -- [e-mail]

use v5.26;
use Object::Pad 0.57;

package Device::Chip::SSD1306::SPI4 0.12;
class Device::Chip::SSD1306::SPI4
   :isa(Device::Chip::SSD1306);

use Future::AsyncAwait;

=head1 NAME

C - use a F OLED driver in 4-wire SPI mode

=head1 DESCRIPTION

This L subclass provides specific communication to an
F chip attached via SPI in 4-wire mode; using the C pin.

For actually interacting with the attached module, see the main
L documentation.

=cut

use constant PROTOCOL => "SPI";

method SPI_options
{
   return (
      mode => 0,
      max_bitrate => 1E6,
   );
}

=head1 MOUNT PARAMETERS

=head2 dc

The name of the GPIO line on the adapter that is connected to the C pin
of the chip.

=cut

method mount ( $adapter, %params )
{
   $self->{dc} = delete $params{dc} or
      die "Require a 'dc' parameter";

   return $self->SUPER::mount( $adapter, %params );
}

# passthrough
method power ( $on ) { $self->protocol->power( $on ) }

method set_dc ( $dc )
{
   $self->protocol->write_gpios( { $self->{dc} => $dc } );
}

async method send_cmd ( @vals )
{
   await $self->set_dc( 0 );
   await $self->protocol->readwrite( join "", map { chr } @vals );
}

async method send_data ( $bytes )
{
   await $self->set_dc( 1 );
   await $self->protocol->readwrite( $bytes );
}

=head1 AUTHOR

Paul Evans

=cut

0x55AA;