File Coverage

blib/lib/Devel/KYTProf/Logger/XRay.pm

Criterion	Covered	Total	%
statement	31	35	88.5
branch	4	8	50.0
condition			n/a
subroutine	7	7	100.0
pod	0	1	0.0
total	42	51	82.3

package Devel::KYTProf::Logger::XRay;

use 5.012000;
use strict;
use warnings;

use AWS::XRay;
use Devel::KYTProf;
use Time::HiRes();

our $VERSION = "0.02";

sub log {
    my ($class, %args) = @_;

    return if !$AWS::XRay::ENABLED;

    my $segment = AWS::XRay::Segment->new({
        name => $args{module},
    });
    my $elapsed   = $args{time} / 1000; # msec -> sec
    my $end       = Time::HiRes::time();
    my $start     = $end - $elapsed;
    $segment->{start_time} = $start;
    $segment->{end_time}   = $end;

    my $data = $args{data};
    if (exists $data->{http_method}) {
        $segment->{http} = {
            request => {
                method => $data->{http_method},
                url    => $data->{http_url},
            },
        };
    }
    elsif (exists $data->{sql}) {
        $segment->{sql} = {
            sanitized_query => delete $data->{sql},
        };
        $segment->{metadata} = $data;
    }
    else {
        $segment->{metadata} = $data;
    }
    eval {
        $segment->close();
    };
    if ($@) {
        warn $@;
    }
}

1;
__END__