File Coverage

blib/lib/DateTimeX/Start.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	8	8	100.0
condition	10	11	90.9
subroutine	13	13	100.0
pod	4	4	100.0
total	79	80	98.7

package DateTimeX::Start;

use strict;
use warnings;

use version; our $VERSION = qv('v1.2.0');

use DateTime           qw( );
use DateTime::TimeZone qw( );
use Exporter           qw( import );
use Scalar::Util       qw( );


my @long  = qw( start_of_date start_of_month start_of_year start_of_today );
my @short = qw( date month year today );
our @EXPORT_OK = ( @long, @short );
our %EXPORT_TAGS = (
   'ALL'   => \@EXPORT_OK,
   'long'  => \@long,
   'short' => \@short,
);


sub _start_of_date {
   my ($trunc, $dt, $tz) = @_;

   if (Scalar::Util::blessed($dt)) {
      $tz ||= $dt->time_zone;
      $dt = $dt->clone->set_time_zone('floating')->truncate( to => $trunc )
         if $trunc;
   } else {
      $tz ||= 'local';
      $dt = DateTime->new( year => $dt->[0], month => $dt->[1] || 1, day => $dt->[2] || 1 );
   }

   $tz = DateTime::TimeZone->new( name => $tz )
      if !ref($tz);

   my $target_day = ( $dt->local_rd_values )[0];
   my $min_epoch = int($dt->epoch()/60) - 24*60;
   my $max_epoch = int($dt->epoch()/60) + 24*60;
   while ($max_epoch - $min_epoch > 1) {
      my $epoch = ( $min_epoch + $max_epoch ) >> 1;
      if (( DateTime->from_epoch( epoch => $epoch*60, time_zone => $tz )->local_rd_values )[0] < $target_day) {
         $min_epoch = $epoch;
      } else {
         $max_epoch = $epoch;
      }
   }

   return DateTime->from_epoch(epoch => $max_epoch*60, time_zone => $tz);
}

sub start_of_date  { _start_of_date(undef,   @_) }
sub start_of_month { _start_of_date('month', @_) }
sub start_of_year  { _start_of_date('year',  @_) }
sub start_of_today { _start_of_date(undef, DateTime->now( time_zone => $_[0] || 'local' )) }

{
   no warnings qw( once );
   *date  = \&start_of_date;
   *month = \&start_of_month;
   *year  = \&start_of_year;
   *today = \&start_of_today;
}


1;

__END__