File Coverage

blib/lib/DateTime/Tiny.pm

Criterion	Covered	Total	%
statement	34	43	79.0
branch	14	16	87.5
condition	1	3	33.3
subroutine	17	20	85.0
pod	12	12	100.0
total	78	94	82.9

use strict;
use warnings;
package DateTime::Tiny;
# ABSTRACT:  A date object, with as little code as possible

our $VERSION = '1.05'; # TRIAL

use overload 'bool' => sub () { 1 };
use overload '""'   => 'as_string';
use overload 'eq'   => sub { "$_[0]" eq "$_[1]" };
use overload 'ne'   => sub { "$_[0]" ne "$_[1]" };

#####################################################################
# Constructor and Accessors

#pod =pod
#pod
#pod =method new
#pod
#pod   my $date = DateTime::Tiny->new(
#pod       year   => 2006,
#pod       month  => 12,
#pod       day    => 31,
#pod       hour   => 10,
#pod       minute => 45,
#pod       second => 32,
#pod       );
#pod
#pod The C constructor creates a new B object.
#pod
#pod It takes six named parameters. C should be the day of the month (1-31),
#pod C should be the month of the year (1-12), C as a 4 digit year.
#pod C should be the hour of the day (0-23), C should be the
#pod minute of the hour (0-59) and C should be the second of the
#pod minute (0-59).
#pod
#pod These are the only parameters accepted.
#pod
#pod Returns a new B object.
#pod
#pod =cut

sub new {
	my $class = shift;
	bless { @_ }, $class;
}

#pod =pod
#pod
#pod =method now
#pod
#pod   my $current_date = DateTime::Tiny->now;
#pod
#pod The C method creates a new date object for the current date.
#pod
#pod The date created will be based on localtime, despite the fact that
#pod the date is created in the floating time zone.
#pod
#pod Returns a new B object.
#pod
#pod =cut

sub now {
	my @t = localtime time;
	shift->new(
		year   => $t[5] + 1900,
		month  => $t[4] + 1,
		day    => $t[3],
		hour   => $t[2],
		minute => $t[1],
		second => $t[0],
	);
}

#pod =pod
#pod
#pod =method year
#pod
#pod The C accessor returns the 4-digit year for the date.
#pod
#pod =cut

sub year {
	defined $_[0]->{year} ? $_[0]->{year} : 1970;
}

#pod =pod
#pod
#pod =method month
#pod
#pod The C accessor returns the 1-12 month of the year for the date.
#pod
#pod =cut

sub month {
	$_[0]->{month} || 1;
}

#pod =pod
#pod
#pod =method day
#pod
#pod The C accessor returns the 1-31 day of the month for the date.
#pod
#pod =cut

sub day {
	$_[0]->{day} || 1;
}

#pod =pod
#pod
#pod =method hour
#pod
#pod The C accessor returns the hour component of the time as
#pod an integer from zero to twenty-three (0-23) in line with 24-hour
#pod time.
#pod
#pod =cut

sub hour {
	$_[0]->{hour} || 0;
}

#pod =pod
#pod
#pod =method minute
#pod
#pod The C accessor returns the minute component of the time
#pod as an integer from zero to fifty-nine (0-59).
#pod
#pod =cut

sub minute {
	$_[0]->{minute} || 0;
}

#pod =pod
#pod
#pod =method second
#pod
#pod The C accessor returns the second component of the time
#pod as an integer from zero to fifty-nine (0-59).
#pod
#pod =cut

sub second {
	$_[0]->{second} || 0;
}

#pod =pod
#pod
#pod =method ymdhms
#pod
#pod The C method returns the most common and accurate stringified date
#pod format, which returns in the form "2006-04-12T23:59:59".
#pod
#pod =cut

sub ymdhms {
	sprintf( "%04u-%02u-%02uT%02u:%02u:%02u",
		$_[0]->year,
		$_[0]->month,
		$_[0]->day,
		$_[0]->hour,
		$_[0]->minute,
		$_[0]->second,
	);
}





#####################################################################
# Type Conversion

#pod =pod
#pod
#pod =method from_string
#pod
#pod The C method creates a new B object from a string.
#pod
#pod The string is expected to be an ISO 8601 combined date and time, with
#pod separators (including the 'T' separator) and no time zone designator.  No
#pod other ISO 8601 formats are supported.
#pod
#pod   my $almost_midnight = DateTime::Tiny->from_string( '2006-12-20T23:59:59' );
#pod
#pod Returns a new B object, or throws an exception on error.
#pod
#pod =cut

sub from_string {
	my $string = $_[1];
	unless ( defined $string and ! ref $string ) {
		require Carp;
		Carp::croak("Did not provide a string to from_string");
	}
	unless ( $string =~ /^(\d\d\d\d)-(\d\d)-(\d\d)T(\d\d):(\d\d):(\d\d)$/ ) {
		require Carp;
		Carp::croak("Invalid time format (does not match ISO 8601)");
	}
	$_[0]->new(
		year   => $1 + 0,
		month  => $2 + 0,
		day    => $3 + 0,
		hour   => $4 + 0,
		minute => $5 + 0,
		second => $6 + 0,
	);
}

#pod =pod
#pod
#pod =method as_string
#pod
#pod The C method converts the date to the default string, which
#pod at present is the same as that returned by the C method above.
#pod
#pod This string conforms to the ISO 8601 standard for the encoding of a combined
#pod date and time as a string, without time-zone designator.
#pod
#pod =cut

sub as_string {
	$_[0]->ymdhms;
}

#pod =pod
#pod
#pod =method DateTime
#pod
#pod The C method is used to create a L object
#pod that is equivalent to the B object, for use in
#pod conversions and calculations.
#pod
#pod As mentioned earlier, the object will be set to the 'C' locale,
#pod and the 'floating' time zone.
#pod
#pod If installed, the L module will be loaded automatically.
#pod
#pod Returns a L object, or throws an exception if L
#pod is not installed on the current host.
#pod
#pod =cut

sub DateTime {
	require DateTime;
	my $self = shift;
	DateTime->new(
		day       => $self->day,
		month     => $self->month,
		year      => $self->year,
		hour      => $self->hour,
		minute    => $self->minute,
		second    => $self->second,
		locale    => 'C',
		time_zone => 'floating',
		@_,
	);
}

1;

__END__