File Coverage

blib/lib/Date/Holidays/SK.pm

Criterion	Covered	Total	%
statement	43	47	91.4
branch	20	22	90.9
condition			n/a
subroutine	7	8	87.5
pod	3	3	100.0
total	73	80	91.2

package Date::Holidays::SK;

use strict;
use warnings;

our $VERSION = '0.02';

use Date::Simple;
use Date::Easter;

use Exporter qw(import);
our @EXPORT_OK = qw(
   is_sk_holiday
   is_sk_holiday_today
   sk_holidays
);

# Fixed-date holidays {'MMDD' => 'NAME'}
my $FIX = {
   '0101' => 'Deň vzniku Slovenskej republiky',
   '0106' => 'Zjavenie Pána (Traja králi)',
   '0501' => 'Sviatok práce',
   '0508' => 'Deň víťazstva nad fašizmom',
   '0705' => 'Sviatok svätého Cyrila a Metoda',
   '0829' => 'Výročie SNP',
   '0901' => 'Deň Ústavy Slovenskej republiky',
   '0915' => 'Sedembolestná Panna Mária',
   '1101' => 'Sviatok všetkých svätých',
   '1117' => 'Deň boja za slobodu a demokraciu',
   '1224' => 'Štedrý deň',
   '1225' => 'Prvý sviatok vianočný',
   '1226' => 'Druhý sviatok vianočný',
};

# The only variable-date holiday is Easter Monday and Easter Friday -- we deal with that separately
my $EF = 'Veľkonočný piatok';
my $EM = 'Veľkonočný pondelok';

sub is_sk_holiday {
   my ($year, $month, $day) = @_;

   my $k = sprintf "%02d%02d", $month, $day;

   # for fixed dates
   return $FIX->{$k}
      if exists $FIX->{$k};

   my $diff = Date::Simple->new($year, $month, $day) - Date::Simple->new($year, easter($year));
   # Easter Sunday +1 -> Easter Monday.
   return $EM if ( $diff == 1 );
   # Easter Sunday -2 -> Easter Friday.
   return $EF if ( $diff == -2 );

   return 0;
}

sub sk_holidays {

   my ($year, $month, $day) = @_;

   my $easter = Date::Simple->new($year, easter($year));
   # Easter Monday is the day after Easter
   my $em = $easter + 1;
   # Easter Friday is 2 days before Easter
   my $ef = $easter - 2;

   # Easter Key ($ek) is a string in the form 'MMDD'
   my $emk = sprintf "%02d%02d", $em->month, $em->day;
   my $efk = sprintf "%02d%02d", $ef->month, $ef->day;

   # $h is a reference to a hash containing the results
   my $h;

   if ( ! $month ) {

      #print "DEBUG: only year given\n";
      $h = {%$FIX};
      $h->{$emk} = $EM;
      $h->{$efk} = $EF;

   } elsif ( ! $day ) {

      #print "DEBUG: only year and month given\n";
      my $m = sprintf "%02d", $month;
      foreach my $k (keys %$FIX) {
         $h->{$k} = $FIX->{$k} if $k =~ m/\A$m/;
      }
      $h->{$emk} = $EM if $emk =~ m/\A$m/;
      $h->{$efk} = $EF if $efk =~ m/\A$m/;

   } else {

      #print "DEBUG: year, month, and day given\n";
      my $k = sprintf "%02d%02d", $month, $day;
      $h->{$k} = $FIX->{$k} if exists $FIX->{$k};
      $h->{$emk} = $EM if $emk == $k;
      $h->{$efk} = $EF if $efk == $k;

   }

   return $h;
}

sub is_sk_holiday_today {
   my ($year, $month, $day) = (localtime)[ 5, 4, 3 ];
   $year  += 1900;
   $month += 1;
   return is_sk_holiday( $year, $month, $day );
}

1;

__END__