File Coverage

blib/lib/Date/Holidays/AT.pm

Criterion	Covered	Total	%
statement	18	102	17.6
branch	0	12	0.0
condition	0	3	0.0
subroutine	6	8	75.0
pod	0	1	0.0
total	24	126	19.0

package Date::Holidays::AT;

use warnings;
use strict;

# Stock modules
use Time::Local;
use POSIX qw(strftime);

# Prerequisite
use Date::Calc 5.0 qw(Add_Delta_Days Easter_Sunday Day_of_Week This_Year);

require Exporter;

our @ISA       = qw(Exporter);
our @EXPORT_OK = qw(holidays);
use version; our $VERSION = qv("0.1.4");

sub holidays {
    my %parameters = (
                      YEAR     => This_Year(),
                      WHERE    => ['common'],
                      FORMAT   => "%s",
                      WEEKENDS => 1,
                      @_,
                     );

    # Easter is the key to everything
    my ($year, $month, $day) = Easter_Sunday($parameters{'YEAR'});

    # Aliases for holidays
    #
    # neuj = New year's day
    # hl3k = Heilige 3 Koenige
    # jose = Josef
    # tdar = Staatsfeiertag (Tag der Arbeit)
    # flor = Florian
    # mahi = Mariae Himmelfahrt
    # rupe = Rupert
    # volk = Tag der Volksabstimmung
    # nati = Nationalfeiertag
    # alhe = Allerheiligen
    # mart = Martin
    # leop = Leopold
    # maem = Mariae Empfaengnis
    # heab = Heiliger Abend
    # chri = Christtag
    # stef = Stefanitag
    # silv = Silvester
    # karf = Karfreitag
    # ostm = Ostermontag
    # himm = Christi Himmelfahrt
    # pfim = Pfingstmontag
    # fron = Fronleichnam

    # Fixed-date holidays
    #
    my (%holiday, %holidays);

    $holiday{'neuj'} = _date2timestamp($year, 1,  1);     # New year's day
    $holiday{'hl3k'} = _date2timestamp($year, 1,  6);     # Heilige 3 Koenige
    $holiday{'jose'} = _date2timestamp($year, 3,  19);    # Josef
    $holiday{'tdar'} = _date2timestamp($year, 5,  1);     # Staatsfeiertag (Tag der Arbeit)
    $holiday{'flor'} = _date2timestamp($year, 5,  4);     # Florian
    $holiday{'mahi'} = _date2timestamp($year, 8,  15);    # Mariae Himmelfahrt
    $holiday{'rupe'} = _date2timestamp($year, 9,  24);    # Rupert
    $holiday{'volk'} = _date2timestamp($year, 10, 10);    # Tag der Volksabstimmung
    $holiday{'nati'} = _date2timestamp($year, 10, 26);    # Nationalfeiertag
    $holiday{'alhe'} = _date2timestamp($year, 11, 1);     # Allerheiligen
    $holiday{'mart'} = _date2timestamp($year, 11, 11);    # Martin
    $holiday{'leop'} = _date2timestamp($year, 11, 15);    # Leopold
    $holiday{'maem'} = _date2timestamp($year, 12, 8);     # Mariae Empfaengnis
    $holiday{'heab'} = _date2timestamp($year, 12, 24);    # Heiliger Abend
    $holiday{'chri'} = _date2timestamp($year, 12, 25);    # Christtag
    $holiday{'stef'} = _date2timestamp($year, 12, 26);    # Stefanitag
    $holiday{'silv'} = _date2timestamp($year, 12, 31);    # Silvester

    # Holidays relative to Easter
    #
    # Karfreitag (Good Friday) = Easter Sunday minus 2 days
    my ($j_karf, $m_karf, $t_karf) = Date::Calc::Add_Delta_Days($year, $month, $day, -2);
    $holiday{'karf'} = _date2timestamp($j_karf, $m_karf, $t_karf);

    # Ostermontag (Easter Monday) = Easter Sunday plus 1 day
    my ($j_ostm, $m_ostm, $t_ostm) = Date::Calc::Add_Delta_Days($year, $month, $day, 1);
    $holiday{'ostm'} = _date2timestamp($j_ostm, $m_ostm, $t_ostm);

    # Christi Himmelfahrt (Ascension Day) = Easter Sunday plus 39 days
    my ($j_himm, $m_himm, $t_himm) = Date::Calc::Add_Delta_Days($year, $month, $day, 39);
    $holiday{'himm'} = _date2timestamp($j_himm, $m_himm, $t_himm);

    # Pfingsmontag (Whit Monday) = Easter Sunday plus 50 days
    my ($j_pfim, $m_pfim, $t_pfim) = Date::Calc::Add_Delta_Days($year, $month, $day, 50);
    $holiday{'pfim'} = _date2timestamp($j_pfim, $m_pfim, $t_pfim);

    # Fronleichnam (Corpus Christi) = Easter Sunday plus 60 days
    my ($j_fron, $m_fron, $t_fron) = Date::Calc::Add_Delta_Days($year, $month, $day, 60);
    $holiday{'fron'} = _date2timestamp($j_fron, $m_fron, $t_fron);

    # Common holidays througout Austria
    @{ $holidays{'common'} } = qw(neuj hl3k ostm tdar himm pfim fron mahi nati alhe maem chri stef);


    # Extra for Burgenland
    @{ $holidays{'B'} } =   qw(jose karf mart heab silv );
    # Extra for Kaernten
    @{ $holidays{'K'} } =   qw(     karf volk heab silv );
    # Extra for Niederoesterreich
    @{ $holidays{'NOE'} } = qw(     karf leop heab silv );
    # Extra for Oberoesterreich
    @{ $holidays{'OOE'} } = qw(     karf flor heab silv );
    # Extra for Salzburg
    @{ $holidays{'S'} } =   qw(     karf rupe heab silv );
    # Extra for Steiermark
    @{ $holidays{'ST'} } =  qw(jose karf      heab silv );
    # Extra for Tirol
    @{ $holidays{'T'} } =   qw(jose karf      heab silv );
    # Extra for Voralberg
    @{ $holidays{'V'} } =   qw(jose karf      heab silv );
    # Extra for Wien
    @{ $holidays{'W'} } =   qw(     karf leop heab silv );

    # Build list for returning
    #
    my %holidaylist;
    # See what holidays shall be printed
    my $wantall = 0;
    foreach (@{$parameters{'WHERE'}}){
        if ($_ eq 'all'){
            $wantall = 1;
        }
    }
    if (1 == $wantall){
        # All holidays if 'all' is in the WHERE parameter list.
        %holidaylist = %holiday;
    }else{
        # Only specified regions
        foreach my $scope (@{$parameters{'WHERE'}}){
            foreach my $alias(@{$holidays{$scope}}){
                $holidaylist{$alias} = $holiday{$alias};
            }
        }
    }


    # Add the most obscure holidays that were requested through
    # the ADD parameter
    if ($parameters{'ADD'}) {
        foreach my $add (@{ $parameters{'ADD'} }) {
            $holidaylist{$add} = $holiday{$add};
        }
    }

    # If WEEKENDS => 0 was passed, weed out holidays on weekends
    #
    unless (1 == $parameters{'WEEKENDS'}) {

        # Walk the list of holidays
        foreach my $alias (keys(%holidaylist)) {

            # Get day of week. Since we're no longer
            # in Date::Calc's world, use localtime()
            my $dow = (localtime($holiday{$alias}))[6];

            # dow 6 = Saturday, dow 0 = Sunday
            if ((6 == $dow) or (0 == $dow)) {

                # Kick this day from the list
                delete $holidaylist{$alias};
            }
        }
    }

    # Sort values stored in the hash for returning
    #
    my @returnlist;
    foreach (sort { $holidaylist{$a} <=> $holidaylist{$b} } (keys(%holidaylist))) {

        # See if this platform has strftime(%s)
        # if not, inject seconds manually into format string.
        my $formatstring = $parameters{'FORMAT'};
        if (strftime('%s', localtime($holidaylist{$_})) eq '%s') {
            $formatstring =~ s/%{0}%s/$holidaylist{$_}/g;
        }

        # Inject the holiday's alias name into the format string
        # if it was requested by adding %#.
        $formatstring =~ s/%{0}%#/$_/;
        push @returnlist, strftime($formatstring, localtime($holidaylist{$_}));
    }
    return \@returnlist;
}

sub _date2timestamp {

    # Turn Date::Calc's y/m/d format into a UNIX timestamp
    my ($y, $m, $d) = @_;
    my $timestamp = timelocal(0, 0, 0, $d, ($m - 1), $y);
    return $timestamp;
}

1;
__END__