File Coverage

blib/lib/DataDog/DogStatsd/Helper.pm

Criterion	Covered	Total	%
statement	50	51	98.0
branch	14	16	87.5
condition	8	9	88.8
subroutine	15	15	100.0
pod	9	10	90.0
total	96	101	95.0

package DataDog::DogStatsd::Helper;

use strict;
use warnings;
our $VERSION = '0.06';

use base qw( Exporter );
our @EXPORT_OK = qw/stats_inc stats_dec stats_timing stats_gauge stats_count stats_histogram stats_event stats_timed/;

use DataDog::DogStatsd;
use Time::HiRes qw(tv_interval gettimeofday);

## no critic (Subroutines::RequireFinalReturn)
sub stats_inc {
    my @args = @_;
    # support stats_inc('test.blabla', 0.1); as well
    if (@args > 1 and $args[1] =~ /^[\d\.]+$/) {
        # actually ppl wants stats_count
        warn "stats_inc sample_rate makes no sense for more than 1\n" if $args[1] > 1;
        $args[1] = {sample_rate => $args[1]};
    }
    get_dogstatsd()->increment(@args);
}
sub stats_dec    { get_dogstatsd()->decrement(@_); }

sub stats_timing {
    my @args = @_;
    # support stats_timing('connection_time', 1000 * $interval, 0.1); as well
    if (@args > 2 and $args[2] =~ /^[\d\.]+$/) {
        # actually ppl wants stats_count
        warn "stats_timing sample_rate makes no sense for more than 1\n" if $args[2] > 1;
        $args[2] = {sample_rate => $args[2]};
    }
    get_dogstatsd()->timing(@args);
}

sub stats_timed (&@) {    ## no critic (ProhibitSubroutinePrototypes)
    my ($sub, $what, $opts) = splice @_, 0, 3;

    my $start = [gettimeofday];

    my (@res, $no_ex);
    if (wantarray) {
        $no_ex = eval { @res = $sub->(@_); 1; };
    } elsif (defined wantarray) {
        $no_ex = eval { $res[0] = $sub->(@_); 1; };
    } else {
        $no_ex = eval { $sub->(@_); 1; };
    }

    if ($no_ex) {
        get_dogstatsd()->timing($what, 1000 * tv_interval($start), $opts);
    } else {
        get_dogstatsd()->increment("$what.failure", $opts);
        die $@;
    }

    return wantarray ? @res : $res[0];
}

sub stats_gauge      { get_dogstatsd()->gauge(@_); }
sub stats_count      { get_dogstatsd()->count(@_); }
sub stats_histogram  { get_dogstatsd()->histogram(@_); }
sub stats_event      { get_dogstatsd()->event(@_); }

my $DOGSTATSD;
sub get_dogstatsd {
    $DOGSTATSD ||= DataDog::DogStatsd->new(
        host        => $ENV{DATADOG_AGENT_HOST},
        port        => $ENV{DATADOG_AGENT_PORT},
        namespace   => $ENV{DATADOG_AGENT_NAMESPACE}
        );
    return $DOGSTATSD;
}

sub set_dogstatsd {
    $DOGSTATSD = pop;
}

1;
__END__