File Coverage

blib/lib/Data/Random/NL.pm

Criterion	Covered	Total	%
statement	64	65	98.4
branch	11	14	78.5
condition	3	3	100.0
subroutine	11	11	100.0
pod	4	4	100.0
total	93	97	95.8

package Data::Random::NL;
use warnings;
use strict;

# ABSTRACT: Tools for generating random Dutch numbers
our $VERSION = '1.5';

use Exporter qw(import);
use Carp qw(croak);

our @EXPORT_OK = (
    qw(
        generate_bsn
        generate_rsin
        generate_kvk
        generate_vestigingsnummer
    ),
);

our %EXPORT_TAGS = (
    all => \@EXPORT_OK,
);

sub generate_bsn {
    my $begin = shift;
    my @bsn = _generate_number_set(9, $begin);

    # A BSN cannot start with a 00
    while ($bsn[0] == 0 && $bsn[1] == 0) {
        $bsn[1] = int(rand(10));
    }

    @bsn = reverse(@bsn);

    my $sum = 0;
    foreach my $i (reverse(1..8)) {
        $sum += (($i + 1) * $bsn[$i]);
    }

    my $last_number = $sum % 11;
    # if the last number is 10, we have an invalid number
    return generate_bsn($begin) if $last_number > 9;

    @bsn = reverse(@bsn);

    $bsn[-1] = $last_number;
    return join("", @bsn);
}

sub generate_kvk {
    my $begin = shift;
    my @kvk = _generate_number_set(9, 0, $begin);
    $kvk[0] = 0; # we always start with a 0

    @kvk = _get_last_number(@kvk);
    if (@kvk) {
        shift @kvk;
        return join("", @kvk);
    }
    return generate_kvk($begin);
}

sub generate_rsin {
    my $begin = shift;
    my @rsin = _generate_number_set(9, $begin);

    @rsin = _get_last_number(@rsin);
    return join("", @rsin) if @rsin;
    return generate_rsin($begin);
}

sub _get_last_number {
    my @set = @_;

    @set = reverse(@set);

    my $sum = 0;
    foreach my $i (reverse(1..8)) {
        $sum += (($i + 1) * $set[$i]);
    }

    my $left = $sum % 11;
    my $last_number = abs($left - 11);

    # if the last number is 10, we have an invalid number
    return if $last_number > 9;

    $set[0] = $last_number;
    return reverse(@set);
}

sub _generate_number_set {
    my ($max, @begin) = @_;
    my @number;
    foreach (@begin) {
        eval { _starts_with(\@number, $_) };
        croak "$@" if $@;
    }

    while(@number < $max) {
        push(@number, int(rand(10)));
    }
    return @number;
}

sub generate_vestigingsnummer {
    my $begin = shift;
    return join("", _generate_number_set(12, $begin));
}

sub _starts_with {
    my ($ref, $begin) = @_;

    if (defined $begin) {
        if ($begin !~ /^[0-9]$/) {
            die("You did not provide a number", $/);
        }
        push(@$ref, $begin);
        return 1;
    }
}

1;

__END__