File Coverage

blib/lib/Data/Phrasebook/Loader.pm

Criterion	Covered	Total	%
statement	37	38	97.3
branch	9	10	90.0
condition	2	2	100.0
subroutine	7	7	100.0
pod	1	1	100.0
total	56	58	96.5

package Data::Phrasebook::Loader;
use strict;
use warnings FATAL => 'all';
use base qw( Data::Phrasebook::Debug );
use Carp qw( croak );

use Module::Pluggable   search_path => ['Data::Phrasebook::Loader'];

use vars qw($VERSION);
$VERSION = '0.35';

=head1 NAME

Data::Phrasebook::Loader - Plugin Loader module

=head1 SYNOPSIS

  my $loader = Data::Phrasebook::Loader->new( class => 'Text' );

=head1 DESCRIPTION

C acts as an autoloader for phrasebook plugins.

=head1 CONSTRUCTOR

=head2 new

C takes one optional named argument: the class. It returns a new
instance to the class. Any further arguments to C are given to
the C method of the appropriate class.

If no class is specified the default class of 'Text' is used.

  my $loader = Data::Phrasebook::Loader->new();

  OR

  my $loader = Data::Phrasebook::Loader->new( class => 'Text' );

=cut

my $DEFAULT_CLASS = 'Text';

sub new {
    my $self  = shift;
    my %args  = @_;
    my $class = delete $args{class} || 'Text';

    if($self->debug) {
		$self->store(3,"$self->new IN");
		$self->store(4,"$self->new class=[$class]");
	}

    # in the event we have been subclassed
    $self->search_path( add => "$self" );

    my $plugin;
    my @plugins = $self->plugins();
    for(@plugins) {
        $plugin = $_    if($_ =~ /\b$class$/);
    }

    croak("no loader available of that name\n") unless($plugin);

    eval {
        (my $file = $plugin) =~ s|::|/|g;
        require $file . '.pm';
        $plugin->import();
        1;
    } or do {
        croak "Couldn't require $plugin : $@";
    };

    $self->store(4,"$self->new plugin=[$plugin]")	if($self->debug);
    return $plugin->new( %args );
}

1;

__END__