File Coverage

blib/lib/Data/Pack.pm

Criterion	Covered	Total	%
statement	38	41	92.6
branch	17	20	85.0
condition			n/a
subroutine	9	10	90.0
pod	4	4	100.0
total	68	75	90.6

use 5.008;
use strict;
use warnings;

package Data::Pack;
BEGIN {
  $Data::Pack::VERSION = '1.101611';
}

# ABSTRACT: Pack data structures so only real content remains
use Scalar::Util 'reftype';
use Exporter qw(import);
our %EXPORT_TAGS = (util => [qw(pack_data pack_hash pack_array has_content)],);
our @EXPORT_OK = @{ $EXPORT_TAGS{all} = [ map { @$_ } values %EXPORT_TAGS ] };

sub has_content {
    my $data = shift;
    return defined $data unless ref $data;
    my $type = reftype $data;
    return @$data if $type eq 'ARRAY';
    return keys %$data if $type eq 'HASH';
    die "has_content: unknown type [$type]\n";
}

sub pack_data {
    my $data = shift;
    return $data unless ref $data;
    my $type = reftype $data;
    if ($type eq 'HASH') {
        my $packed_hash = {};
        while (my ($key, $value) = each %$data) {
            my $packed_value = pack_data($value);
            next unless has_content($packed_value);
            $packed_hash->{$key} = $packed_value;
        }
        bless $packed_hash, ref $data unless ref $data eq 'HASH';
        return wantarray ? %$packed_hash : $packed_hash;
    } elsif ($type eq 'ARRAY') {
        my $packed_array =
          [ grep { defined } map { scalar(pack_data($_)) } @$data ];
        return wantarray ? @$packed_array : $packed_array;
    } else {
        die "pack_hash: unknown type [$type]\n";
    }
}

sub pack_hash {
    my %h = @_;
    pack_data(\%h);
}

sub pack_array {
    pack_data(\@_);
}
1;


__END__