File Coverage

blib/lib/Data/InputMonster/Util.pm

Criterion	Covered	Total	%
statement	26	29	89.6
branch	14	18	77.7
condition	7	9	77.7
subroutine	6	7	85.7
pod	1	1	100.0
total	54	64	84.3

use strict;
use warnings;
package Data::InputMonster::Util 0.011;
# ABSTRACT: handy routines for use with the input monster
use Sub::Exporter::Util qw(curry_method);

use Sub::Exporter -setup => {
  exports => {
    dig => curry_method,
  },
};

#pod =head1 DESCRIPTION
#pod
#pod These methods, which provide some helpers for use with InputMonster, can be
#pod exported as routines upon request.
#pod
#pod =cut

#pod =method dig
#pod
#pod   my $source = dig( [ $key1, $key2, $key2 ]);
#pod   my $source = dig( sub { ... } );
#pod
#pod A C source looks through the input using the given locator.  If it's a
#pod coderef, the code is called and passed the input.  If it's an arrayref, each
#pod entry is used, in turn, to subscript the input as a deep data structure.  If
#pod it's a plain scalar, it's treated like a one-element arrayref would have been.
#pod
#pod For example, given:
#pod
#pod   $input  = [ { ... }, { ... }, { foo => [ { bar => 13, baz => undef } ] } ];
#pod   $source = dig( [ qw( 2 foo 0 bar ) ] );
#pod
#pod The source would find 13.
#pod
#pod =cut

sub dig {
  my ($self, $locator) = @_;

  Carp::confess("no locator given") unless defined $locator;

  $locator = [ $locator ] unless ref $locator;

  if (ref $locator eq 'CODE') {
    return sub { $locator->($_[1]) };
  } elsif (ref $locator eq 'ARRAY') {
    return sub {
      my ($monster, $input) = @_;
      my $next = $input;

      for my $k (@$locator) {
        return unless my $ref = ref $next;
        return unless $ref and (($ref eq 'ARRAY') or ($ref eq 'HASH'));

        return if $ref eq 'ARRAY' and $k !~ /\A-?\d+\z/;
        $next = $next->[ $k ] if $ref eq 'ARRAY';
        $next = $next->{ $k } if $ref eq 'HASH';
      }

      return $next;
    };
  }

  Carp::confess("locator must be either a code or array reference");
}

'hi, domm!';

__END__