File Coverage

blib/lib/Data/Focus/Lens/HashArray/Recurse.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	12	12	100.0
condition			n/a
subroutine	9	9	100.0
pod	2	2	100.0
total	60	60	100.0

package Data::Focus::Lens::HashArray::Recurse;
use strict;
use warnings;
use parent qw(Data::Focus::Lens);

sub new {
    my ($class, %args) = @_;
    my $self = bless {
        immutable => !!$args{immutable}
    }, $class;
    return $self;
}

sub _set_array {
    my ($self, $whole, @parts) = @_;
    return $whole if !@parts;
    if($self->{immutable}) {
        return \@parts;
    }else {
        @$whole = @parts;
        return $whole;
    }
}

sub _set_hash {
    my ($self, $whole, $keys, @parts) = @_;
    return $whole if !@parts;
    my $ret = $self->{immutable} ? {%$whole} : $whole;
    $ret->{$keys->[$_]} = $parts[$_] foreach 0 .. $#$keys;
    return $ret;
}

sub apply_lens {
    my ($self, $app_class, $part_mapper, $data) = @_;
    my $type = ref($data);
    if($type eq "ARRAY") {
        my @fparts = map { $self->apply_lens($app_class, $part_mapper, $_) } @$data;
        return $app_class->build(sub {
            $self->_set_array($data, @_);
        }, @fparts);
    }elsif($type eq "HASH") {
        my @keys = keys %$data;
        my @fparts = map { $self->apply_lens($app_class, $part_mapper, $_) } @{$data}{@keys};
        return $app_class->build(sub {
            $self->_set_hash($data, \@keys, @_);
        }, @fparts);
    }else {
        return $part_mapper->($data);
    }
}

1;
__END__