File Coverage

blib/lib/Data/Fake/Dates.pm

Criterion	Covered	Total	%
statement	27	27	100.0
branch			n/a
condition	4	4	100.0
subroutine	13	13	100.0
pod	4	4	100.0
total	48	48	100.0

use 5.008001;
use strict;
use warnings;

package Data::Fake::Dates;
# ABSTRACT: Fake date data generators

our $VERSION = '0.006';

use Exporter 5.57 qw/import/;

our @EXPORT = qw(
  fake_past_epoch
  fake_future_epoch
  fake_past_datetime
  fake_future_datetime
);

use Time::Piece 1.27; # portability fixes

sub _past { int( rand(time) ) }

sub _future {
    my $now = time;
    return $now + int( rand($now) );
}

#pod =func fake_past_epoch
#pod
#pod     $generator = fake_past_epoch();
#pod
#pod This returns a generator that gives a randomly-selected integer number of
#pod seconds between the Unix epoch and the current time.
#pod
#pod =cut

sub fake_past_epoch { \&_past }

#pod =func fake_future_epoch
#pod
#pod     $generator = fake_future_epoch();
#pod
#pod This returns a generator that gives a randomly-selected integer number of
#pod seconds between the the current time and a period as far into the future as
#pod the Unix epoch is in the past (i.e. about 45 years as of 2015).
#pod
#pod =cut

sub fake_future_epoch { \&_future }

#pod =func fake_past_datetime
#pod
#pod     $generator = fake_past_datetime();
#pod     $generator = fake_past_datetime("%Y-%m-%d");
#pod     $generator = fake_past_datetime($strftime_format);
#pod
#pod This returns a generator that selects a past datetime like
#pod C does but formats it as a string using FreeBSD-style
#pod C formats.  (See L for details.)
#pod
#pod The default format is ISO8601 UTC "Zulu" time (C<%Y-%m-%dT%TZ>).
#pod
#pod =cut

sub fake_past_datetime {
    my ($format) = @_;
    $format ||= "%Y-%m-%dT%H:%M:%SZ";
    return sub {
        Time::Piece->strptime( _past(), "%s" )->strftime($format);
    };
}

#pod =func fake_future_datetime
#pod
#pod     $generator = fake_future_datetime();
#pod     $generator = fake_future_datetime("%Y-%m-%d");
#pod     $generator = fake_future_datetime($strftime_format);
#pod
#pod This returns a generator that selects a future datetime like
#pod C does but formats it as a string using FreeBSD-style
#pod C formats.  (See L for details.)
#pod
#pod The default format is ISO8601 UTC "Zulu" time (C<%Y-%m-%dT%TZ>).
#pod
#pod =cut

sub fake_future_datetime {
    my ($format) = @_;
    $format ||= "%Y-%m-%dT%H:%M:%SZ";
    return sub {
        Time::Piece->strptime( _future(), "%s" )->strftime($format);
    };
}


# vim: ts=4 sts=4 sw=4 et tw=75:

__END__