File Coverage

lib/Data/Dumper/Store.pm

Criterion	Covered	Total	%
statement	44	46	95.6
branch	9	14	64.2
condition	2	6	33.3
subroutine	11	12	91.6
pod	6	6	100.0
total	72	84	85.7

package Data::Dumper::Store;

use strict;
use warnings;
use 5.010;

use Data::Dumper;

$Data::Dumper::Purity = 1;
$Data::Dumper::Terse = 1;

=head1 NAME

    Data::Dumper::Store - persistent key-value storage engine based on Data::Dumper serialization mechanism and flat files.

=head1 VERSION

    Version 1.01

=cut

our $VERSION = '1.01';

sub new {
    my ($class, %opts) = @_;

    defined $opts{file} or die "File is not specified";

    my $self = {
        file => $opts{file},
        data => {},
    };
    _init($self);

    return bless $self, $class;
}

sub _init {
    my ($self) = @_;

    return unless -e $self->{file};
    open my $fh, '<', $self->{file}
        or return;
    my $text = do { local $/; <$fh> };
    my $data = eval($text);

    return if $@;

    $self->{data} = $data;
}

sub init {
    my ($self, $data) = @_;

    defined $data && ref $data && ref $data eq 'HASH' or return;
    $self->{data} = $data;

    return $self;
}

sub set {
    my ($self, $key, $val) = @_;

    $self->{data}{$key} = $val;

    return $self;
}

sub get {
    my ($self, $key) = @_;

    return unless $key;

    return $self->{data}{$key};
}

sub dump {
    my ($self) = @_;

    return Dumper $self->{data};
}

sub commit {
    my ($self) = @_;

    open my $fh, ">", $self->{file} or return;

    print {$fh} Dumper $self->{data};
    close $fh;

    return 1;
}

sub DESTROY {
    my ($self) = @_;

    $self->commit();
}

1;

__END__