File Coverage

blib/lib/Data/ConveyorBelt.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	9	12	75.0
condition	7	10	70.0
subroutine	8	8	100.0
pod	3	3	100.0
total	68	74	91.8

package Data::ConveyorBelt;
use strict;
use 5.008_001;

use base qw( Class::Accessor::Fast );

our $VERSION = '0.02';

__PACKAGE__->mk_accessors(qw( getter filters ));

use Carp qw( croak );
use List::Util qw( min );

sub new {
    my $class = shift;
    my $machine = $class->SUPER::new(@_);
    $machine->filters( [ ] )
        unless defined $machine->filters;
    return $machine;
}

sub add_filter {
    push @{ shift->filters }, $_[0];
}

sub fetch {
    my $machine = shift;
    my(%param) = @_;

    my $limit = $param{limit} or croak "limit is required";
    my $offset = $param{offset} || 0;
    my $chunk_size = $param{chunk_size} || $limit;

    my $getter = $machine->getter or croak "No getter defined";
    my $filters = $machine->filters || [];

    my @data;
    my $need = $limit + $offset;
    my $off = 0;
    while ( @data < $need ) {
        my $data = $getter->( $chunk_size, $off );
        last unless $data && @$data;

        ## If we asked for $chunk_size results and got back fewer, we know
        ## that there aren't any more.
        my $got_enough = @$data >= $chunk_size ? 1 : 0;

        for my $filter ( @$filters ) {
            $data = $filter->( $data );
        }
        push @data, @$data;

        last unless $got_enough;

        $off += $chunk_size;
    }

    return [ @data[ $offset .. min($#data, $need - 1) ] ];
}

1;
__END__