File Coverage

blib/lib/Dancer2/Session/MongoDB.pm

Criterion	Covered	Total	%
statement	20	39	51.2
branch			n/a
condition			n/a
subroutine	7	14	50.0
pod			n/a
total	27	53	50.9

use 5.008001;
use strict;
use warnings;

package Dancer2::Session::MongoDB;
# ABSTRACT: Dancer 2 session storage with MongoDB
our $VERSION = '0.004';

use Moo;
use MongoDB::MongoClient;
use MongoDB::OID;
use Dancer2::Core::Types;

#--------------------------------------------------------------------------#
# Public attributes
#--------------------------------------------------------------------------#

#pod =attr database_name (required)
#pod
#pod Name of the database to hold the sessions collection.
#pod
#pod =cut

has database_name => (
    is       => 'ro',
    isa      => Str,
    required => 1,
);

#pod =attr collection_name
#pod
#pod Collection name for storing session data. Defaults to 'dancer_sessions'.
#pod
#pod =cut

has collection_name => (
    is      => 'ro',
    isa     => Str,
    default => sub { "dancer_sessions" },
);

#pod =attr client_options
#pod
#pod Hash reference of configuration options to pass through to
#pod L constructor.  See that module for details on
#pod configuring authentication, replication, etc.
#pod
#pod =cut

has client_options => (
    is      => 'ro',
    isa     => HashRef,
    default => sub { {} },
);

#--------------------------------------------------------------------------#
# Private attributes
#--------------------------------------------------------------------------#

has _client => (
    is  => 'lazy',
    isa => InstanceOf ['MongoDB::MongoClient'],
);

sub _build__client {
    my ($self) = @_;
    return MongoDB::MongoClient->new( $self->client_options );
}

has _collection => (
    is  => 'lazy',
    isa => InstanceOf ['MongoDB::Collection'],
);

sub _build__collection {
    my ($self) = @_;
    my $db = $self->_client->get_database( $self->database_name );
    return $db->get_collection( $self->collection_name );
}

#--------------------------------------------------------------------------#
# Role composition
#--------------------------------------------------------------------------#

with 'Dancer2::Core::Role::SessionFactory';

# When saving/retrieving, we need to add/strip the _id parameter
# because the Dancer2::Core::Session object keeps them as separate
# attributes

sub _retrieve {
    my ( $self, $id ) = @_;
    my $doc = $self->_collection->find_one( { _id => $id } );
    return $doc->{data};
}

sub _flush {
    my ( $self, $id, $data ) = @_;
    $self->_collection->save( { _id => $id, data => $data }, { safe => 1 } );
}

sub _destroy {
    my ( $self, $id ) = @_;
    $self->_collection->remove( { _id => $id }, { safe => 1 } );
}

sub _sessions {
    my ($self) = @_;
    my $cursor = $self->_collection->query->fields( { _id => 1 } );
    return [ map { $_->{_id} } $cursor->all ];
}

sub _change_id {
    my ( $self, $old_id, $new_id ) = @_;
    $self->_flush( $new_id, $self->_retrieve( $old_id ) );
    $self->_destroy( $old_id );
}

1;


# vim: ts=4 sts=4 sw=4 et:

__END__