File Coverage

blib/lib/Dancer2/Plugin/Queue/Role/Test.pm

Criterion	Covered	Total	%
statement	36	42	85.7
branch			n/a
condition			n/a
subroutine	11	12	91.6
pod			n/a
total	47	54	87.0

use 5.008001;
use strict;
use warnings;

package Dancer2::Plugin::Queue::Role::Test;
# ABSTRACT: A Test::Roo::Role for testing Queue backends
our $VERSION = '0.004'; # VERSION

use Test::Roo::Role;
use MooX::Types::MooseLike::Base qw/Str HashRef CodeRef/;

use HTTP::Tiny;
use Test::TCP;


has backend => (
    is       => 'ro',
    isa      => Str,
    required => 1,
);


has options => (
    is      => 'lazy',
    isa     => HashRef,
);

sub _build_options { }

has _server => (
    is  => 'lazy',
    isa => CodeRef,
);

sub _build__server {
    my ($self) = @_;
    return sub {
        package
            MyServer;
        use Dancer2 ':syntax';
        use Dancer2::Plugin::Queue;
        my $port = shift;

        set confdir      => '.';
        set startup_info => 0;
        set show_errors  => 1;
        set plugins      => {
            Queue => {
                default => {
                    class   => $self->backend,
                    options => $self->options,
                },
            }
        };

        get '/add' => sub {
            queue->add_msg( params->{msg} );
            my ( $msg, $body ) = queue->get_msg;
            queue->remove_msg($msg);
            return $body;
        };

        Dancer2->runner->server->port($port);
        start;
    };
}

test 'queue and dequeue' => sub {
    my $self = shift;
    test_tcp(
        client => sub {
            my $port = shift;
            my $url  = "http://localhost:$port/";

            my $ua = HTTP::Tiny->new;

            my $res = $ua->get( $url . "add?msg=Hello%20World" );
            like $res->{content}, qr/Hello World/i, "sent and receieved message";
        },
        server => $self->_server,
    );
};

1;


# vim: ts=4 sts=4 sw=4 et:

__END__