File Coverage

blib/lib/Dancer2/Plugin/ProgressStatus.pm

Criterion	Covered	Total	%
statement	63	76	82.8
branch	16	30	53.3
condition	3	12	25.0
subroutine	14	15	93.3
pod			n/a
total	96	133	72.1

# ABSTRACT: Keeps track of progress status

package Dancer2::Plugin::ProgressStatus;
$Dancer2::Plugin::ProgressStatus::VERSION = '0.016';
use strict;
use warnings;

use Digest::MD5 qw/md5_hex/;
use Path::Tiny;
use File::Path qw//;
use Carp;
use JSON qw//;

use Dancer2::Plugin;
use Dancer2::Plugin::ProgressStatus::Object;
use Dancer2::Core::Response;

sub _progress_status_file {
    my ( $dsl, $name ) = @_;

    my $dir = $dsl->config->{'plugins'}->{ProgressStatus}->{dir}
                or croak 'No ProgressStatus plugin settings in config';
    if ( !-d $dir ) {
        File::Path::make_path($dir) or die "Cannot create path $dir";
    }

    return Path::Tiny::path($dir, md5_hex($name));
}


on_plugin_import {
    my $dsl = shift;

    # determine if there is a prefix?

    # Register the route for fetching messages
    $dsl->app->add_route(
        method  => 'get',
        regexp  => '/_progress_status/:name',
        code    => sub {
            my $context = shift;
            my $data = _get_progress_status_data($dsl, $context->request->params->{'name'});

            return Dancer2::Core::Response->new(
                status       => 200,
                content      => JSON->new->encode($data),
                content_type => 'application/json',
            );
        },
    );
};

sub _get_progress_status_data {
    my ($dsl, $name) = @_;

    my $file = $dsl->_progress_status_file($name);
    if ( !$file->is_file ) {
        return {
            error  => "No such progress status $name",
            status => 'error',
        };
    }
    my $data = JSON->new->decode($file->slurp_utf8());
    delete $data->{pid};

    return $data;
}


register start_progress_status => sub {
    my ($dsl, $args) = @_;

    if ( !ref($args) ) {
        $args = { name => $args };
    }

    my $progress_id = $dsl->params->{progress_id};
    my $name        = delete $args->{name};
    if ( !$name && !$progress_id ) {
        croak 'Must supply name and/or progress_id';
    }
    $name .= $progress_id if $progress_id;

    my $file = $dsl->_progress_status_file($name);
    if ( $file->is_file ) {
        my $d = JSON->new->decode($file->slurp_utf8());
        my $in_progress = $d->{in_progress};

        if ( $in_progress && $d->{pid} != $$ ) {
            if ( kill(0, $d->{pid}) ) {
                die "Progress status $name already exists for a running process, cannot create a new one\n";
            }
        }
        elsif ( $in_progress ) {
            die "Progress status $name already exists\n";
        }
    }

    my %objargs = (
        _on_save => sub {
            my ($obj, $is_finished) = @_;
            my $data = JSON->new->encode({
                start_time  => $obj->start_time,
                current_time  => $obj->current_time,
                total       => $obj->total,
                count       => $obj->count,
                messages    => $obj->messages,
                in_progress => $is_finished ? JSON::false : JSON::true,
                status      => $obj->status,
                pid         => $$,
            });

            $file->spew_utf8($data);
        },
    );

    foreach my $key (qw/total count status messages/) {
        if ( $args->{$key} ) {
            $objargs{$key} = $args->{$key};
        }
    }

    my $obj = Dancer2::Plugin::ProgressStatus::Object->new(%objargs);
    $obj->save();
    return $obj;
};

register is_progress_running => sub {
    my ( $dsl, $name ) = @_;
    my $file = $dsl->_progress_status_file($name);

    if ( $file->exists ) {
        my $d = JSON->new->decode($file->slurp_utf8());
        my $in_progress = $d->{in_progress};

        if ( $in_progress && $d->{pid} != $$ && kill(0, $d->{pid}) ) {
            return 1;
        }
    }
    return 0;
};


register_plugin;


1;

__END__