File Coverage

blib/lib/Dancer2/Plugin/MobileDevice.pm

Criterion	Covered	Total	%
statement	29	29	100.0
branch	8	8	100.0
condition	4	4	100.0
subroutine	8	8	100.0
pod	2	2	100.0
total	51	51	100.0

package Dancer2::Plugin::MobileDevice;

use strict;
use warnings;

our $VERSION = "0.000003";

=head1 NAME

Dancer2::Plugin::MobileDevice - Make a Dancer2 app mobile-aware

=cut

use Dancer2::Plugin;

plugin_keywords qw(is_mobile_device);

sub is_mobile_device {
    my $self = shift;
    return (($self->dsl->request->user_agent || '')
        =~ /(?:iP(?:ad|od|hone)|Android|BlackBerry|Mobile|Palm)/) || 0 ;
} #is_mobile_device

sub BUILD {
    my $self = shift;

    # Change the layout setting.  Save the old to reset the setting later.
    # We check config->{mobile_layout} within the hook rather than outside
    # so that the plugin will respond correctly if mobile_layout is
    # changed between requests.
    $self->dsl->hook('before',
        sub {
            return unless $self->config->{mobile_layout};
            return unless $self->is_mobile_device;
            my $mobile_layout = $self->config->{mobile_layout};
            $self->dsl->debug("Using mobile layout $mobile_layout");

            $self->dsl->request->var(orig_layout => $self->dsl->setting('layout'));
            $self->dsl->setting(layout => $mobile_layout);
        }
    );

    # After a request, reset the layout for the benefit of future requests.
    # Don't check the state of the request just in case the mobile_layout
    # has changed between the beginning and the end of the request (although
    # I'm not sure how that could happen!).
    $self->dsl->hook('after',
        sub {
            my $vars = $self->dsl->request->vars;
            return unless exists $vars->{orig_layout};
                # Can't check truthiness, since undef is a valid
                # orig_layout value.

            $self->dsl->log(debug => "resetting layout to " .
                ($vars->{orig_layout} || ''));
            $self->dsl->setting(layout => $vars->{orig_layout});
        }
    );

    # Make variable 'is_mobile_device' available in templates
    $self->dsl->hook('before_template_render',
        sub {
            my $tokens = shift;
            $self->dsl->request->var(is_mobile_device => $self->is_mobile_device);
            $tokens->{'is_mobile_device'} = $self->is_mobile_device;

            $self->dsl->log(debug => 'Requester ' .
                ($self->is_mobile_device ? 'is' : 'is not') .
                ' mobile device');
        }
    );

} #BUILD

1;
__END__