File Coverage

blib/lib/Dancer2/Logger/Syslog.pm

Criterion	Covered	Total	%
statement	25	25	100.0
branch			n/a
condition	4	9	44.4
subroutine	7	7	100.0
pod	1	1	100.0
total	37	42	88.1

package Dancer2::Logger::Syslog;
# ABSTRACT: Dancer2 logger engine for Sys::Syslog
$Dancer2::Logger::Syslog::VERSION = '0.3';

use Moo;
use File::Basename 'basename';
use Sys::Syslog;

use Dancer2::Core::Types;

with 'Dancer2::Core::Role::Logger';

has 'log_open' => (
    is      => 'ro',
    isa     => Bool,
    lazy    => 1,
    builder => '_syslog_open',
);

# Set by calling function
has facility => (
    is      => 'ro',
    isa     => Str,
    lazy    => 1,
);

has ident => (
    is      => 'ro',
    isa     => Str,
    lazy    => 1,
);

has logopt => (
    is      => 'ro',
    isa     => Str,
    lazy    => 1,
);

sub _syslog_open {
    my $self = shift;

    my $facility = $self->facility || 'USER';
    my $ident    = $self->ident
                     || $self->app_name
                     || $ENV{DANCER_APPDIR}
                     || basename($0);
    my $logopt   = $self->logopt   || 'pid';

    openlog($ident, $logopt, $facility);
    1; # openlog() will have croaked if it can't connect
}

sub DESTROY { closelog() }

sub log {
    my ($self, $level, $message) = @_;

    $self->log_open;

    my $syslog_levels = {
        core    => 'debug',
        debug   => 'debug',
        warning => 'warning',
        error   => 'err',
        info    => 'info',
    };

    $level = $syslog_levels->{$level} || 'debug';
    my $fm = $self->format_message($level => $message);
    syslog($level, $fm);
}

1;

__END__