File Coverage

blib/lib/Dancer/Plugin/WindowSession.pm

Criterion	Covered	Total	%
statement	18	41	43.9
branch	0	14	0.0
condition			n/a
subroutine	6	9	66.6
pod			n/a
total	24	64	37.5

package Dancer::Plugin::WindowSession;

use strict;
use warnings;
use Clone;
use Carp;

our $VERSION = '0.02';

use Dancer ':syntax';
use Dancer::Plugin;

sub _get_window_session_object
{
	my $win_sess_id ; ## The window session ID, from the HTTP request.
	my $win_sess_obj ; ## The Dancer::Session::Abstract object

	## Is there a cached version of the window-session object ?
	if (defined(var 'window_session_object')) {
		$win_sess_obj = var 'window_session_object';
		$win_sess_id = $win_sess_obj->id;
		return $win_sess_obj;
	}


	# This is the first time 'window_session' is request during this request handling,
	# check if we have one in the HTTP Request
	$win_sess_id = param 'winsid';

	my $session_engine = engine 'session'
		or die "Can't find session engine";

	# If we have a Window-session-Id, try to retrieve the corresponding hash.
	if ($win_sess_id) {
		$win_sess_obj = $session_engine->retrieve($win_sess_id);

		## If we failed to retrieve existing window-session, force a new one
		$win_sess_id = undef unless $win_sess_obj;
	}

	# If anything failed along the way, just create a new window session
	if (!$win_sess_id) {
		$win_sess_obj = $session_engine->create();
		$win_sess_id = $win_sess_obj->id;

	}
	## Cache the new window-session object,
	## for other route handlers downstream in the current request handling.
	var 'window_session_object' => $win_sess_obj;

	return $win_sess_obj;
}

hook before => sub {
	my $window_session = _get_window_session_object;
	my $window_session_id = $window_session->id;
};

hook before_template_render => sub {
	my $tokens = shift ;

	my $window_session = _get_window_session_object;

	$tokens->{winsid} = $window_session->id;
	$tokens->{window_session} = Clone::clone($window_session);
};

hook after => sub {
	my $window_session = _get_window_session_object;
	my $window_session_id = $window_session->id;
	$window_session->flush();
};

register window_session_id => sub {
	my $window_session = _get_window_session_object;
	return $window_session->id;
};


register window_session => sub {
	my $window_session = _get_window_session_object;
	my $window_session_id = $window_session->id;

	my ($key,$value) = @_;
	$key eq 'id' and croak 'Can\'t store to window_session key with name "id"';

	$window_session->{$key} = $value if (@_==2);
	return $window_session->{$key};
};

register_plugin;

# ABSTRACT: A Dancer plugin for managing Browser Window Sessions

1;
__END__