File Coverage

lib/Dancer/Plugin/Queue.pm

Criterion	Covered	Total	%
statement	29	31	93.5
branch	9	18	50.0
condition	4	8	50.0
subroutine	6	6	100.0
pod			n/a
total	48	63	76.1

use 5.008001;
use strict;
use warnings;

package Dancer::Plugin::Queue;
# ABSTRACT: Dancer plugin for message queue abstractions
our $VERSION = '0.002'; # VERSION

use Dancer::Plugin;
use Class::Load qw/try_load_class/;

my %queues;
my $conf;

register queue => sub {
    my ( $self, $name ) = plugin_args(@_);
    $conf ||= plugin_setting();

    # if name not specified, DWIM or use 'default'
    if ( not defined $name ) {
        if ( keys %$conf == 1 ) {
            ($name) = keys %$conf;
        }
        elsif ( exists $conf->{default} ) {
            $name = "default";
        }
        else {
            die "Can't determine a default queue name";
        }
    }

    # return cached object if already created
    return $queues{$name} if defined $queues{$name};

    # otherwise, instantiate the object from config settings
    my $queue_conf = $conf->{$name}
      or die "No configuration for queue '$name'";

    my $class = $queue_conf->{class}
      or die "No class specified for queue '$name'";

    $class = "Dancer::Plugin::Queue::$class";

    try_load_class($class)
      or die "Queue class '$class' could not be loaded";

    $class->can('DOES') && $class->DOES("Dancer::Plugin::Queue::Role::Queue")
      or die "Queue class '$class' does not implement the expected role";

    my $object = eval { $class->new( $queue_conf->{options} || {} ) }
      or die "Could not create $class object: $@";

    return $queues{$name} = $object;
};

register_plugin;
1;


# vim: ts=4 sts=4 sw=4 et:

__END__