File Coverage

blib/lib/Dancer/Plugin/Captcha/SecurityImage.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

package Dancer::Plugin::Captcha::SecurityImage;
use strict;
use warnings;

our $VERSION = '0.10';

use Carp;
use Dancer ':syntax';
use Dancer::Plugin;
use GD::SecurityImage;

my $conf = plugin_setting;

my $session_engine;

register create_captcha => sub (;$$) {
    my $init = pop || {};
    $init->{$_} ||= $conf->{$_} || {} for qw(new out);
    $init->{$_} ||= $conf->{$_} || [] for qw(create particle);
    my $captcha_id = @_ ? shift : 'default';

    $session_engine ||= engine 'session'
        or croak __PACKAGE__ . " error: there is no session engine configured. "
            . "You need a session engine to be able to use this plugin";

    my $captcha = GD::SecurityImage->new(%{$init->{new}});
    $captcha->random($init->{random});
    $captcha->create(@{$init->{create}});
    $captcha->particle(@{$init->{particle}});
    my ($image_data, $mime_type, $random_number) = $captcha->out(%{$init->{out}});

    _captcha_data($captcha_id, 'string' => $random_number);

    header 'Pragma' => 'no-cache';
    header 'Cache-Control' => 'no-cache';
    content_type $mime_type;
    return $image_data;
};

register validate_captcha => sub ($;$) {
    my $user_input = pop;
    my $captcha_id = @_ ? shift : 'default';

    my $string = _captcha_data($captcha_id, 'string');
    return $user_input && $string && $user_input eq $string;
};

register clear_captcha => sub (;$) {
    my $captcha_id = shift || 'default';
    _captcha_data($captcha_id, 'string' => undef);
};

sub _captcha_data {
    my ($captcha_id, $key, $val) = @_;
    my $session_data = session('captcha') || {};
    $session_data->{$captcha_id} ||= {};
    if ($val) {
        $session_data->{$captcha_id}{$key} = $val;
        session 'captcha' => $session_data;
    }
    return $session_data->{$captcha_id}{$key};
}

register_plugin;

1;
__END__