File Coverage

lib/Dancer/Plugin/Auth/Facebook.pm

Criterion	Covered	Total	%
statement	41	43	95.3
branch	4	8	50.0
condition	3	6	50.0
subroutine	9	9	100.0
pod			n/a
total	57	66	86.3

package Dancer::Plugin::Auth::Facebook;

$Dancer::Plugin::Auth::Facebook::VERSION = '0.08';

use strict;
use warnings;

use Dancer ':syntax';
use Dancer::Plugin;
use Net::Facebook::Oauth2;
use Carp 'croak';

my $_FB;
sub facebook { $_FB }
register 'facebook' => \&facebook;

my $application_id;
my $application_secret;
my $cb_url;
my $cb_success;
my $cb_fail;
my $fb_scope;
my @scope;
my $me_fields;
my $api_version;

register 'auth_fb_init' => sub {
  my $config = plugin_setting;
  $application_id       = $config->{application_id};
  $application_secret   = $config->{application_secret};
  $cb_url               = $config->{callback_url};

  $cb_success           = $config->{callback_success} || '/';
  $cb_fail              = $config->{callback_fail}    || '/fail';
  $fb_scope             = $config->{scope};
  $me_fields            = $config->{fields};
  $api_version          = $config->{api_version} || 'v4.0';

  if (defined $fb_scope) {
    foreach my $fs (split(/\s+/, $fb_scope)) {
      next unless ($fs =~  m/^[_A-Za-z0-9\.]+$/);
      push(@scope, $fs);
    }
  }
  else {
    push(@scope, 'email');
  }

  for my $param (qw/application_id application_secret callback_url/) {
    croak "'$param' is expected but not found in configuration" unless $config->{$param};
  }

  debug "new facebook with $application_id, $application_secret, $cb_url";

  $_FB = Net::Facebook::Oauth2->new(
    api_version => $api_version,
    application_id => $application_id,  ##get this from your facebook developers platform
    application_secret => $application_secret, ##get this from your facebook developers platform
    callback => $cb_url,  ##Callback URL, facebook will redirect users after authintication
  );

};

register 'auth_fb_authenticate_url' => sub {
  if (not defined facebook ) {
    croak "auth_fb_init must be called first";
  }

  my $url = facebook->get_authorization_url(
      scope   => \@scope,
      display => 'page',
  );

  session fb_access_token  => '';
  debug "fb_auth_url: $url";

  return $url;
};

get '/auth/facebook/callback' => sub {
  debug "entering facebook callback";

  return redirect $cb_fail if (params->{'error'} || !params->{'code'});

  my $access_token = session('fb_access_token');

  if (!$access_token) {
    eval {
      $access_token = facebook->get_access_token(code => params->{'code'});
    };
    if (!$access_token) {
      error "facebook error fetching access token: $@";
      return redirect $cb_fail;
    }
    session fb_access_token => $access_token;
  }

  my $fb = Net::Facebook::Oauth2->new(
      api_version => $api_version,
       access_token => $access_token,
  );

  my ($me, $fb_response);
  eval {
    $fb_response = $fb->get( 'https://graph.facebook.com/' . $api_version . '/me' . ($me_fields ? "?fields=$me_fields" : '') );
    $me = $fb_response->as_hash;
  };
  if ($@ || !$me) {
     error "error fetching facebook user: '$@' on response '$fb_response'";
     return redirect $cb_fail;
  }
  else {
    session fb_user => $me;
    return redirect $cb_success;
  }
};

register_plugin;

1;

__END__