File Coverage

blib/lib/DJabberd/Plugin/Balancer.pm

Criterion	Covered	Total	%
statement	18	20	90.0
branch			n/a
condition			n/a
subroutine	6	7	85.7
pod			n/a
total	24	27	88.8

{   package DJabberd::Plugin::Balancer;
    our $VERSION = '0.1';
    use strict;
    use warnings;
    use base qw(DJabberd::Plugin);

    sub register {
        my ($self, $vhost) = @_;
        # here we just re-bless $vhost
        bless $vhost, 'DJabberd::Plugin::Balancer::VHost';
    }
};
{   package DJabberd::Plugin::Balancer::VHost;
    use strict;
    use warnings;
    use base qw(DJabberd::VHost);

    sub register_jid {
        my ($self, $jid, $conn, $cb) = @_;
        my $fullstr = $jid->as_string;

        if (exists $self->{jid2sock}{$fullstr}) {
            $cb->error("conflict");

        } else {
            # XXX: $jid doesn't provide a sane API, but
            # we are going to get inside anyway.
            my $res = $jid->resource;
            $res .= '#'.$conn->{id};
            $jid->[DJabberd::JID::RES()] = $res;
            $jid->[DJabberd::JID::AS_STRING()] = undef;
            $jid->[DJabberd::JID::AS_BSTRING()] = undef;
            $jid->[DJabberd::JID::AS_STREXML()] = undef;

            $self->{balancejid}{$fullstr} ||= [];
            push @{$self->{balancejid}{$fullstr}}, $jid->as_string;

            return $self->SUPER::register_jid($jid, $conn, $cb);
        }
    }

    sub find_jid {
        my ($self, $jid) = @_;
        my $fullstr = $jid;

        if (exists $self->{balancejid}{$fullstr}) {
            my $item = int(rand(scalar(@{$self->{balancejid}{$fullstr}})));
            return $self->SUPER::find_jid($self->{balancejid}{$fullstr}[$item]);
        } else {
            return $self->SUPER::find_jid($jid);
        }
    }

    sub unregister_jid {
        my ($self, $jid, $conn) = @_;
        my $fullstr = $jid->as_string;
        my $balancejid = $fullstr;
        if ($balancejid =~ s/#[^#]+$//) {
            if (exists $self->{balancejid}{$balancejid}) {
                @{$self->{balancejid}{$balancejid}} =
                  grep { $fullstr ne $_ }
                    @{$self->{balancejid}{$balancejid}};
            }
        }
        return $self->SUPER::unregister_jid($jid, $conn);
    }

};

__PACKAGE__

__END__