File Coverage

blib/lib/DJabberd/Authen/DBI.pm

Criterion	Covered	Total	%
statement	13	15	86.6
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	18	20	90.0

package DJabberd::Authen::DBI;
use strict;
use warnings;
use base 'DJabberd::Authen';

use Digest::MD5 qw(md5_hex md5_base64);
use Digest::SHA1 qw(sha1_hex sha1_base64);
use DJabberd::Log;
our $logger = DJabberd::Log->get_logger;
use DBI;

our $VERSION = '0.2';

sub log {
    $logger;
}

# configuration loading
BEGIN {
    no strict 'refs';
    for my $name qw(dsn user pass query args) {
        *{"set_config_".$name} = sub {
            my $self = shift;
            $self->{$name} = shift if @_;
            $self->{$name};
        }
    }
}

sub blocking { 1; }
sub can_register_jids { 0; }
sub can_unregister_jids { 0; }
sub can_retrieve_cleartext { 0; }

# finalize configuration
sub finalize {
    my $self = shift;

    die 'No database configured.' unless $self->{dsn};
    die 'No query specified.' unless $self->{query};

    $self->{dbi} = DBI->connect(map { $self->{$_} } qw(dsn user pass))
      or die 'Error connectin to the database. '.$DBI::errstr;
    $logger->debug('Connected to database '.$self->{dsn});

    $self->{sth} = $self->{dbi}->prepare($self->{query})
      or die 'Error preparing statement. '.$self->{dbi}->errstr;
    $logger->debug('Query prepared '.$self->{dsn});

}

sub check_cleartext {
    my ($self, $cb, %args) = @_;
    my $username = $args{username};
    my $password = $args{password};
    my $conn = $args{conn};
    unless ($username =~ /^\w+$/) {
        $cb->reject;
        return;
    }

    my %arguments =
      ( login => $username,
        password => $password,
        password_sha1_hex => sha1_hex($password),
        password_sha1_base64 => sha1_base64($password),
        password_md5_hex => md5_hex($password),
        password_md5_base64 => md5_base64($password) );

    $self->{sth}->execute
      ( map { $arguments{$_} } split /,/, $self->{args} )
        or do {
            $logger->debug('Error Executing query '.$self->{dbi}->errstr);
            $cb->reject();
            return
        };

    if (my ($data) = $self->{sth}->fetchrow_array) {
        $logger->debug('User '.$username.' authenticated');
        $cb->accept();
    } else {
        $logger->debug('Failed authentication for user '.$username);
        $cb->reject();
    }

}

1;

__END__