File Coverage

blib/lib/DBIx/TransactionManager/Extended.pm

Criterion	Covered	Total	%
statement	89	89	100.0
branch	30	30	100.0
condition			n/a
subroutine	18	18	100.0
pod	7	9	77.7
total	144	146	98.6

package DBIx::TransactionManager::Extended;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.02";

use parent qw/DBIx::TransactionManager/;

use Carp qw/croak/;
use DBIx::TransactionManager::Extended::Txn;

# override
sub new { shift->SUPER::new(@_)->_initialize }

sub _initialize {
    my $self = shift;
    $self->{_in_commit_after_hook} = 0;
    $self->{_context_data}         = {};
    $self->{_hooks_before_commit}  = [];
    $self->{_hooks_after_commit}   = [];
    $self;
}

sub context_data {
    my $self = shift;
    croak 'CANNOT call context_data out of the transaction' unless $self->in_transaction;
    return $self->{_context_data};
}

# override
sub txn_scope { DBIx::TransactionManager::Extended::Txn->new(@_) }

# override
sub txn_commit {
    my $self = shift;
    return $self->SUPER::txn_commit() if @{ $self->active_transactions } != 1;

    my $context_data        = $self->{_context_data};
    my $hooks_before_commit = $self->{_hooks_before_commit};
    my $hooks_after_commit  = $self->{_hooks_after_commit};

    if (@$hooks_before_commit) {
        eval { $_->($context_data) for @$hooks_before_commit };
        if ($@) {
            $self->txn_rollback();
            croak $@;
        }
        @$hooks_before_commit = ();
    }

    my $ret = eval {
        $self->SUPER::txn_commit();
    };
    if ($@) {
        $self->_reset_all();
        croak $@;
    }

    if (@$hooks_after_commit) {
        local $self->{_in_commit_after_hook} = $self->{_in_commit_after_hook} + 1;
        if ($self->{_in_commit_after_hook} == 1) {
            eval { $_->($context_data) for @$hooks_after_commit };
            if ($@) {
                $self->_reset_all();
                croak $@;
            }
            @$hooks_after_commit = ();
        }
    }
    %$context_data = ();

    return $ret;
}

# override
sub txn_rollback {
    my $self = shift;
    $self->_reset_all();
    $self->SUPER::txn_rollback();
}

sub _reset_all {
    %{$_[0]->{_context_data}}
        = @{$_[0]->{_hooks_before_commit}}
        = @{$_[0]->{_hooks_after_commit}}
        = ();
}

sub add_hook_before_commit {
    my ($self, $hook) = @_;
    croak 'CANNOT call add_hook_before_commit out of the transaction' unless $self->in_transaction;
    push @{ $self->{_hooks_before_commit} } => $hook;
    return $hook;
}

sub add_hook_after_commit {
    my ($self, $hook) = @_;
    croak 'CANNOT call add_hook_after_commit out of the transaction' unless $self->in_transaction;
    push @{ $self->{_hooks_after_commit} } => $hook;
    return $hook;
}

sub remove_hook_before_commit {
    my ($self, $hook) = @_;
    croak 'CANNOT call remove_hook_before_commit out of the transaction' unless $self->in_transaction;
    _remove_hook($self->{_hooks_before_commit}, $hook);
}

sub remove_hook_after_commit {
    my ($self, $hook) = @_;
    croak 'CANNOT call remove_hook_after_commit out of the transaction' unless $self->in_transaction;
    _remove_hook($self->{_hooks_after_commit}, $hook);
}

sub _remove_hook {
    my ($hooks, $hook) = @_;

    my $found;
    for my $i (0..$#{$hooks}) {
        if ($hook == $hooks->[$i]) {
            $found = $i;
            last;
        }
    }
    splice @$hooks, $found, 1 if $found;
    return $found ? $hook : undef;
}

1;
__END__