File Coverage

blib/lib/DBIx/ThinSQL.pm

Criterion	Covered	Total	%
statement	359	467	76.8
branch	118	172	68.6
condition	9	26	34.6
subroutine	58	94	61.7
pod	6	25	24.0
total	550	784	70.1

package DBIx::ThinSQL;
use strict;
use warnings;
use DBI;
use Exporter::Tidy
  other => [qw/ bv qv qi sq func OR AND /],
  sql   => [
    qw/
      case
      cast
      coalesce
      concat
      count
      exists
      hex
      length
      lower
      ltrim
      max
      min
      replace
      rtrim
      substr
      sum
      upper
      /
  ];

our @ISA     = 'DBI';
our $VERSION = '0.0.45_2';

sub ejoin {
    my $joiner = shift;
    return unless @_;

    my @tokens = map { $_, $joiner } @_;
    pop @tokens;

    return @tokens;
}

sub func {
    my $func   = uc shift;
    my $joiner = shift;

    return DBIx::ThinSQL::expr->new( $func, '(',
        DBIx::ThinSQL::ejoin( $joiner, @_ ), ')' );
}

sub bv { DBIx::ThinSQL::expr->new( DBIx::ThinSQL::bind_value->new(@_) ) }

sub qv { DBIx::ThinSQL::expr->new( DBIx::ThinSQL::quote_value->new(@_) ) }

sub qi { DBIx::ThinSQL::expr->new( DBIx::ThinSQL::quote_identifier->new(@_) ) }

sub OR { ' OR ' }

sub AND { ' AND ' }

sub cast { func( 'cast', ' ', @_ ) }

sub case { DBIx::ThinSQL::case->new(@_) }

sub coalesce { func( 'coalesce', ', ', @_ ) }

sub concat { DBIx::ThinSQL::expr->new( DBIx::ThinSQL::ejoin( ' || ', @_ ) ) }

sub count { func( 'count', ', ', @_ ) }

sub exists { func( 'exists', ', ', @_ ) }

sub hex { func( 'hex', ', ', @_ ) }

sub length { func( 'length', ', ', @_ ) }

sub lower { func( 'lower', ', ', @_ ) }

sub ltrim { func( 'ltrim', ', ', @_ ) }

sub max { func( 'max', ', ', @_ ) }

sub min { func( 'min', ', ', @_ ) }

sub replace { func( 'replace', ', ', @_ ) }

sub rtrim { func( 'rtrim', ', ', @_ ) }

sub substr { func( 'substr', ', ', @_ ) }

sub sq { DBIx::ThinSQL::query->new(@_) }

sub sum { func( 'sum', '', @_ ) }

sub upper { func( 'upper', ', ', @_ ) }

package DBIx::ThinSQL::db;
use strict;
use warnings;
use Carp ();
use Log::Any '$log';
use DBIx::ThinSQL::Driver;

our @ISA = qw(DBI::db);
our @CARP_NOT;

sub share_dir {
    require Path::Tiny;

    return Path::Tiny::path($DBIX::ThinSQL::SHARE_DIR)
      if defined $DBIX::ThinSQL::SHARE_DIR;

    require File::ShareDir;
    return Path::Tiny::path( File::ShareDir::dist_dir('DBIx-ThinSQL') );
}

sub throw_error {
    my $self = shift;
    Carp::croak(@_);
}

sub sql_bv {
    my $self   = shift;
    my $sql    = shift;
    my $bv     = shift;
    my $val    = shift;
    my $prefix = shift;

    $prefix = '' unless length($prefix);

    my $ref     = ref $val;
    my $prefix2 = $prefix . '    ';

    # When we call ourself we already have a ref

    if ( $ref eq '' ) {
        $$sql .= defined $val ? $val : 'NULL';
    }
    elsif ( $ref eq 'DBIx::ThinSQL::query' ) {
        my $bracket = length($prefix) ? '(' : '';
        foreach my $pair ( $val->tokens ) {
            $$sql .= "\n" if $pair->[0] =~ /UNION/;
            my $join_on = length( $pair->[0] )
              && ( $pair->[0] =~ m/(JOIN)|(ON)/ ) ? '  ' : '';
            $$sql .=
              ( $bracket || $prefix . $join_on ) . $pair->[0] . "\n" . $prefix2
              if length( $pair->[0] );
            $self->sql_bv( $sql, $bv, $pair->[1], $prefix2 );
            $$sql .= "\n" if length( $pair->[0] ) or length( $pair->[1] );
            $bracket = '';
        }
        $$sql .= $prefix . ")" if length($prefix);
    }
    elsif ( $ref eq 'DBIx::ThinSQL::list' ) {
        my @tokens = $val->tokens;
        my $last   = pop @tokens;
        my $i      = 0;
        foreach my $token (@tokens) {
            $$sql .= $prefix if $i++;
            $self->sql_bv( $sql, $bv, $token, $prefix );
            $$sql .= ",\n";
        }
        $$sql .= $prefix;
        $self->sql_bv( $sql, $bv, $last, $prefix );
    }
    elsif ( $ref eq 'DBIx::ThinSQL::table' ) {
        my @tokens = $val->tokens;
        my $table  = shift @tokens;
        $$sql .= $table . "(\n";

        my $last = pop @tokens;
        foreach my $token (@tokens) {
            $$sql .= $prefix2;
            $self->sql_bv( $sql, $bv, $token, $prefix2 );
            $$sql .= ",\n";
        }
        $$sql .= $prefix2;
        $self->sql_bv( $sql, $bv, $last, $prefix2 );
        $$sql .= "\n" . $prefix . ")";
    }
    elsif ( $ref eq 'DBIx::ThinSQL::values' ) {
        my @tokens = $val->tokens;
        $$sql .= "(\n";

        my $last = pop @tokens;
        foreach my $token (@tokens) {
            $$sql .= $prefix2;
            $self->sql_bv( $sql, $bv, $token, $prefix2 );
            $$sql .= ",\n";
        }
        $$sql .= $prefix2;
        $self->sql_bv( $sql, $bv, $last, $prefix2 );
        $$sql .= "\n" . $prefix . ")";
    }
    elsif ( $ref eq 'DBIx::ThinSQL::case' ) {
        $$sql .= "CASE\n";
        my @tokens = $val->tokens;
        foreach my $pair (@$val) {
            $$sql .= $prefix2 . $pair->[0] . "\n" . $prefix2 . '    ';
            $self->sql_bv( $sql, $bv, $pair->[1], $prefix2 );
            $$sql .= "\n";
        }
        $$sql .= $prefix . "END";
    }
    elsif ( $ref eq 'DBIx::ThinSQL::expr' ) {
        foreach my $token ( $val->tokens ) {
            $self->sql_bv( $sql, $bv, $token, $prefix );
        }
    }
    elsif ( $ref eq 'DBIx::ThinSQL::bind_value' ) {
        $$sql .= '?';
        push( @{$bv}, $val );
    }
    elsif ( $ref eq 'DBIx::ThinSQL::quote_value' ) {
        $$sql .= $self->quote( $val->for_quote );
    }
    elsif ( $ref eq 'DBIx::ThinSQL::quote_identifier' ) {
        $$sql .= $self->quote_identifier( $val->val );
    }
    else {
        Carp::cluck "sql_bv doesn't know $ref";
    }
}

sub query {
    my $self = shift;
    my ( $sql, @bv ) = ('');
    $self->sql_bv( \$sql, \@bv, DBIx::ThinSQL::query->new(@_) );
    return $sql . ";\n", @bv;
}

sub xprepare {
    my $self = shift;
    Carp::croak('xprepare requires arguments!') unless @_;

    my ( $sql, @bv ) = $self->query(@_);

    # TODO these locals have no effect?
    local $self->{RaiseError}         = 1;
    local $self->{PrintError}         = 0;
    local $self->{ShowErrorStatement} = 1;

    my $prepare_ok;
    my $sth = eval {
        my $sth = $self->prepare($sql);
        $prepare_ok = 1;

        my $i = 1;
        foreach my $bv (@bv) {
            $sth->bind_param( $i++, $bv->for_bind_param );
        }

        $sth;
    };

    if ($@) {
        $log->debug($sql) unless $prepare_ok;
        $self->throw_error($@);
    }

    return $sth;
}

sub xdo {
    my $self = shift;
    my ( $sql, @bv ) = $self->query(@_);

    # TODO these locals have no effect?
    local $self->{RaiseError}         = 1;
    local $self->{PrintError}         = 0;
    local $self->{ShowErrorStatement} = 1;

    return $self->do($sql) unless @bv;

    my $sth = eval {
        my $sth = $self->prepare($sql);
        my $i   = 1;
        foreach my $bv (@bv) {
            $sth->bind_param( $i++, $bv->for_bind_param );
        }

        $sth;
    };

    $self->throw_error($@) if $@;

    return $sth->execute;
}

sub log_debug {
    my $self = shift;
    my $sql  = (shift) . "\n";

    my $sth = $self->prepare( $sql . ';' );
    $sth->execute(@_);

    my $out = join( ', ', @{ $sth->{NAME} } ) . "\n";
    $out .= '  ' . ( '-' x length $out ) . "\n";
    $out .= '  ' . DBI::neat_list($_) . "\n" for @{ $sth->fetchall_arrayref };
    $log->debug($out);
}

sub log_warn {
    my $self = shift;
    my $sql  = (shift) . "\n";

    my $sth = $self->prepare( $sql . ';' );
    $sth->execute(@_);

    my $out = join( ', ', @{ $sth->{NAME} } ) . "\n";
    $out .= '  ' . ( '-' x length $out ) . "\n";
    $out .= '  ' . DBI::neat_list($_) . "\n" for @{ $sth->fetchall_arrayref };
    warn $out;
}

sub dump {
    my $self = shift;
    my $sth  = $self->prepare(shift);
    $sth->execute(@_);
    $sth->dump_results;
}

sub xdump {
    my $self = shift;
    my $sth  = $self->xprepare(@_);
    $sth->execute;
    $sth->dump_results;
}

sub xval {
    my $self = shift;

    my $sth = $self->xprepare(@_);
    $sth->execute;
    my $ref = $sth->arrayref;
    $sth->finish;

    return $ref->[0] if $ref;
    return;
}

sub xvals {
    my $self = shift;
    my $sth  = $self->xprepare(@_);
    $sth->execute;
    return $sth->vals;
}

sub xlist {
    my $self = shift;

    my $sth = $self->xprepare(@_);
    $sth->execute;
    my $ref = $sth->arrayref;
    $sth->finish;

    return @$ref if $ref;
    return;
}

sub xarrayref {
    my $self = shift;

    my $sth = $self->xprepare(@_);
    $sth->execute;
    my $ref = $sth->arrayref;
    $sth->finish;

    return $ref if $ref;
    return;
}

sub xarrayrefs {
    my $self = shift;

    my $sth = $self->xprepare(@_);
    $sth->execute;

    return $sth->arrayrefs;
}

sub xhashref {
    my $self = shift;

    my $sth = $self->xprepare(@_);
    $sth->execute;
    my $ref = $sth->hashref;
    $sth->finish;

    return $ref if $ref;
    return;
}

sub xhashrefs {
    my $self = shift;

    my $sth = $self->xprepare(@_);
    $sth->execute;
    return $sth->hashrefs;
}

# Can't use 'local' to managed txn count here because $self is a tied hashref?
# Also can't use ||=.
sub txn {
    my $self      = shift;
    my $subref    = shift;
    my $wantarray = wantarray;
    my $txn       = $self->{private_DBIx_ThinSQL_txn}++;
    my $driver    = $self->{private_DBIx_ThinSQL_driver};

    $driver ||= $self->{private_DBIx_ThinSQL_driver} = do {
        my $class = 'DBIx::ThinSQL::Driver::' . $self->{Driver}->{Name};
        ( my $path = $class ) =~ s{::}{/}g;
        $path .= '.pm';

        eval { require $path; $class->new } || DBIx::ThinSQL::Driver->new;
    };

    my $current;
    if ( !$txn ) {
        $current = {
            RaiseError         => $self->{RaiseError},
            ShowErrorStatement => $self->{ShowErrorStatement},
        };

    }

    $self->{RaiseError} = 1 unless exists $self->{HandleError};
    $self->{ShowErrorStatement} = 1;

    my @result;
    my $result;

    if ( !$txn ) {
        $self->begin_work;
    }
    else {
        $driver->savepoint( $self, 'txn' . $txn );
    }

    eval {

        if ($wantarray) {
            @result = $subref->();
        }
        else {
            $result = $subref->();
        }

        if ( !$txn ) {

            # We check again for the AutoCommit state in case the
            # $subref did something like its own ->rollback(). This
            # really just prevents a warning from being printed.
            $self->commit unless $self->{AutoCommit};
        }
        else {
            $driver->release( $self, 'txn' . $txn )
              unless $self->{AutoCommit};
        }

    };
    my $error = $@;

    $self->{private_DBIx_ThinSQL_txn} = $txn;
    if ( !$txn ) {
        $self->{RaiseError}         = $current->{RaiseError};
        $self->{ShowErrorStatement} = $current->{ShowErrorStatement};
    }

    if ($error) {

        eval {
            if ( !$txn ) {

                # If the transaction failed at COMMIT, then we can no
                # longer roll back. Maybe put this around the eval for
                # the RELEASE case as well??
                $self->rollback unless $self->{AutoCommit};
            }
            else {
                $driver->rollback_to( $self, 'txn' . $txn )
                  unless $self->{AutoCommit};
            }
        };

        $self->throw_error(
            $error . "\nAdditionally, an error occured during
                  rollback:\n$@"
        ) if $@;

        $self->throw_error($error);
    }

    return $wantarray ? @result : $result;
}

package DBIx::ThinSQL::st;
use strict;
use warnings;

our @ISA = qw(DBI::st);

sub val {
    my $self = shift;
    my $ref = $self->fetchrow_arrayref || return;
    return $ref->[0];
}

sub vals {
    my $self = shift;
    my $all = $self->fetchall_arrayref || return;
    return unless @$all;
    return map { $_->[0] } @$all if wantarray;
    return [ map { $_->[0] } @$all ];
}

sub list {
    my $self = shift;
    my $ref = $self->fetchrow_arrayref || return;
    return @$ref;
}

sub arrayref {
    my $self = shift;
    return unless $self->{Active};
    return $self->fetchrow_arrayref;
}

sub arrayrefs {
    my $self = shift;
    return unless $self->{Active};

    my $all = $self->fetchall_arrayref || return;
    return unless @$all;
    return @$all if wantarray;
    return $all;
}

sub hashref {
    my $self = shift;
    return unless $self->{Active};

    return $self->fetchrow_hashref('NAME_lc');
}

sub hashrefs {
    my $self = shift;
    return unless $self->{Active};

    my @all;
    while ( my $ref = $self->fetchrow_hashref('NAME_lc') ) {
        push( @all, $ref );
    }

    return @all if wantarray;
    return \@all;
}

package DBIx::ThinSQL::bind_value;
use strict;
use warnings;
our @ISA = ('DBIx::ThinSQL::expr');

sub new {
    my $class = shift;
    return $_[0]  if ref( $_[0] ) =~ m/DBIx::ThinSQL/;
    return $$_[0] if ref $_[0] eq 'SCALAR';
    return bless [@_], $class;
}

sub val {
    return $_[0]->[0];
}

sub type {
    return $_[0]->[1];
}

sub for_bind_param {
    my $self = shift;

    # value, type
    return @$self if defined $self->[1];

    # value
    return $self->[0];
}

package DBIx::ThinSQL::quote_value;
use strict;
use warnings;
our @ISA = ('DBIx::ThinSQL::expr');

sub new {
    my $class = shift;
    return $_[0]  if ref( $_[0] ) =~ m/DBIx::ThinSQL/;
    return $$_[0] if ref $_[0] eq 'SCALAR';
    return bless [@_], $class;
}

sub val {
    return $_[0]->[0];
}

sub type {
    return $_[0]->[1];
}

sub for_quote {
    my $self = shift;

    # value, type
    return @$self if defined $self->[1];

    # value
    return $self->[0];
}

package DBIx::ThinSQL::quote_identifier;
use strict;
use warnings;

sub new {
    my $class = shift;
    my $id    = shift;
    return bless \$id, $class;
}

sub val {
    my $self = shift;
    return $$self;
}

package DBIx::ThinSQL::expr;
use strict;
use warnings;

sub new {
    my $class = shift;
    my @tokens;
    foreach my $token (@_) {
        if ( ref $token eq 'ARRAY' ) {
            push( @tokens, DBIx::ThinSQL::query->new(@$token) );
        }
        elsif ( ref $token eq 'HASH' ) {
            my @cols = sort keys %$token;
            my $narg;

            foreach my $col (@cols) {
                if ( ref $token->{$col} eq 'SCALAR' ) {
                    $narg->{$col} = ${ $token->{$col} };
                }
                elsif ( ref $token->{$col} eq 'ARRAY' ) {
                    $narg->{$col} =
                      [ map { DBIx::ThinSQL::bind_value->new($_) }
                          @{ $token->{$col} } ];
                }
                elsif ( defined $token->{$col} ) {
                    $narg->{$col} =
                      DBIx::ThinSQL::bind_value->new( $token->{$col} );
                }
            }

            foreach my $col (@cols) {
                my $val = $narg->{$col};

                my $like     = $col =~ s/\s+like$/ LIKE /i;
                my $not_like = $col =~ s/\s+(!|not)\s*like$/ NOT LIKE /i;
                my $not      = $col =~ s/\s*!$//;
                my $gtlt     = $col =~ s/(\s+[><]=?)$/$1 /;

                push( @tokens, $col );
                if ( !defined $val ) {
                    push( @tokens, ' IS ', $not ? 'NOT NULL' : 'NULL' );
                }
                elsif ( ref $val eq 'ARRAY' ) {
                    push( @tokens, ' NOT' ) if $not;
                    push( @tokens, ' IN (', map { $_, ',' } @$val );
                    pop(@tokens) if @$val;
                    push( @tokens, ')' );
                }
                else {
                    push( @tokens, $not ? ' != ' : ' = ' )
                      unless $like
                      or $not_like
                      or $gtlt;

                    push( @tokens, $val );
                }
                push( @tokens, ' AND ' );
            }
            pop @tokens;
        }
        else {
            push( @tokens, $token );
        }
    }
    return bless \@tokens, $class;
}

sub as {
    my $self  = shift;
    my $value = shift;

    return DBIx::ThinSQL::expr->new( $self, ' AS ',
        DBIx::ThinSQL::quote_identifier->new($value) );
}

sub tokens {
    my $self = shift;
    return @$self;
}

package DBIx::ThinSQL::case;
use strict;
use warnings;
our @ISA = ('DBIx::ThinSQL::expr');

sub new {
    my $class = shift;
    my @tokens;

    while ( my ( $key, $val ) = splice( @_, 0, 2 ) ) {
        ( $key = uc($key) ) =~ s/_/ /g;
        push( @tokens, [ $key, DBIx::ThinSQL::expr->new($val) ] );
    }

    return bless \@tokens, $class;
}

package DBIx::ThinSQL::list;
use strict;
use warnings;

sub new {
    my $class = shift;
    my @tokens;
    foreach my $token (@_) {
        if ( ref $token eq 'ARRAY' ) {
            push( @tokens, DBIx::ThinSQL::query->new(@$token) );
        }
        else {
            push( @tokens, $token );
        }
    }
    return bless \@tokens, $class;
}

sub tokens {
    my $self = shift;
    return @$self;
}

package DBIx::ThinSQL::table;
our @ISA = ('DBIx::ThinSQL::list');

package DBIx::ThinSQL::values;
our @ISA = ('DBIx::ThinSQL::list');

package DBIx::ThinSQL::query;
use strict;
use warnings;

sub new {
    my $class = shift;
    my @query;

    eval {
        while ( my ( $word, $arg ) = splice( @_, 0, 2 ) ) {
            ( $word = uc($word) ) =~ s/_/ /g;
            my $ref = ref $arg;

            if ( $ref =~ m/^DBIx::ThinSQL/ ) {
                push( @query, [ $word, $arg ] );
            }
            elsif ( $ref eq 'ARRAY' ) {
                if ( $word =~ m/((SELECT)|(ORDER)|(GROUP))/ ) {
                    push( @query, [ $word, DBIx::ThinSQL::list->new(@$arg) ] );
                }
                elsif ( $word =~ m/INSERT/ ) {
                    push( @query, [ $word, DBIx::ThinSQL::table->new(@$arg) ] );
                }
                elsif ( $word =~ m/(^AS$)|(FROM)|(JOIN)/ ) {
                    push( @query, [ $word, DBIx::ThinSQL::query->new(@$arg) ] );
                }
                elsif ( $word eq 'VALUES' ) {
                    push(
                        @query,
                        [
                            $word,
                            DBIx::ThinSQL::values->new(
                                map { DBIx::ThinSQL::bind_value->new($_) }
                                  @$arg
                            )
                        ]
                    );
                }
                else {
                    push( @query, [ $word, DBIx::ThinSQL::expr->new(@$arg) ] );
                }
            }
            elsif ( $ref eq 'HASH' ) {

                if ( $word =~ m/^((WHERE)|(ON))/ ) {
                    push( @query, [ $word, DBIx::ThinSQL::expr->new($arg) ] );
                }
                elsif ( $word eq 'SET' ) {
                    my @cols = sort keys %$arg;
                    push(
                        @query,
                        [
                            $word,
                            DBIx::ThinSQL::list->new(
                                map {
                                    DBIx::ThinSQL::expr->new(

                                        # quote_identifier?
                                        $_, ' = ',
                                        ref $arg->{$_} eq 'SCALAR'
                                        ? ${ $arg->{$_} }
                                        : DBIx::ThinSQL::bind_value->new(
                                            $arg->{$_}
                                        )
                                      )
                                } @cols
                            )
                        ]
                    );
                }
                elsif ( $word eq 'VALUES' ) {
                    my @cols = sort keys %$arg;

                    # map quote_identifier?
                    $query[-1]->[1] =
                      DBIx::ThinSQL::table->new( $query[-1]->[1], @cols );

                    push(
                        @query,
                        [
                            $word,
                            DBIx::ThinSQL::values->new(
                                map {
                                    ref $arg->{$_} eq 'SCALAR'
                                      ? ${ $arg->{$_} }
                                      : DBIx::ThinSQL::bind_value->new(
                                        $arg->{$_} )
                                } @cols
                            )
                        ]
                    );
                }
                else {
                    warn "cannot handle $word => HASH";
                }
            }
            else {
                push( @query, [ $word, $arg ] );
            }
        }
    };

    Carp::croak("Bad Query: $@") if $@;
    return bless \@query, $class;
}

sub as {
    my $self  = shift;
    my $value = shift;

    return DBIx::ThinSQL::expr->new( '(', $self, ') AS ',
        DBIx::ThinSQL::quote_identifier->new($value) );
}

sub tokens {
    my $self = shift;
    return @$self;
}

1;

__END__